Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]
Groups > comp.soft-sys.math.mathematica > #11961
| From | Bob Hanlon <hanlonr357@gmail.com> |
|---|---|
| Newsgroups | comp.soft-sys.math.mathematica |
| Subject | Re: Animations in Graphs |
| Date | 2012-10-06 06:05 +0000 |
| Message-ID | <k4ohmd$i5v$1@smc.vnet.net> (permalink) |
| References | <20121005065007.9F8036871@smc.vnet.net> |
| Organization | Time-Warner Telecom |
myR = Table[r, {r, 0, 1, .1}];
u[r_, \[Theta]_] = 1/(2*Pi)*((1 - r^2)/
(1 - 2*r*Cos[\[Theta]] + r^2));
Plot[Evaluate[
Tooltip[u[#, \[Theta]], #] & /@ myR],
{\[Theta], -Pi/2, Pi/2},
PlotRange -> {0, 3.25},
AspectRatio -> 2/3,
Frame -> True,
Axes -> False]
Plot3D[u[r, \[Theta]],
{\[Theta], -Pi/2, Pi/2},
{r, 0, 1},
PlotRange -> {0, 4},
AspectRatio -> 2/3,
ClippingStyle -> None]
Animate[
Plot[u[r, \[Theta]], {\[Theta], -Pi/2, Pi/2},
PlotRange -> {0, 3.25},
GridLines -> Automatic,
Frame -> True,
PlotStyle -> {Thick, Red}],
{r, 0, 1, 0.1},
AnimationRunning -> False]
Manipulate[
Plot[u[r, \[Theta]], {\[Theta], -Pi/2, Pi/2},
PlotRange -> {0, 3.25},
GridLines -> Automatic,
Frame -> True,
PlotStyle -> {Thick, Red}],
{r, 0, 1, 0.01, Appearance -> "Labeled"}]
Bob Hanlon
On Fri, Oct 5, 2012 at 2:50 AM, <psudharaka@gmail.com> wrote:
> Hi everyone,
>
> I produced the following graph but it wont animate.
>
> MyR = Table[r, {r, 0, 1, .1}];
>
> u[\[Theta]_] = 1/(2*Pi)*((1 - r^2)/(1 - 2*r*Cos[\[Theta]] + r^2));
> Plot[u[MyR, \[Theta]], {\[Theta], -Pi/2, Pi/2},
> PlotRange -> {0, 3.25}, PlotStyle -> {Red}, AspectRatio -> 2/3]
>
>
> This following code doesn't produce any errors or Mathematica complaining but nothing happens when I hit play.
>
> Animate[Plot[u[\[Theta]], {\[Theta], -Pi/2, Pi/2}, PlotRange -> {0, 3.25}, GridLines -> Automatic, Frame -> True, PlotStyle -> {Thick, Red}], {r, 0, 1, 0.1}, AnimationRunning -> False]
>
> Thank you and your help is much appreciated.
>
Back to comp.soft-sys.math.mathematica | Previous | Next | Find similar | Unroll thread
Re: Animations in Graphs Bob Hanlon <hanlonr357@gmail.com> - 2012-10-06 06:05 +0000
csiph-web