Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #11961 > unrolled thread

Re: Animations in Graphs

Started byBob Hanlon <hanlonr357@gmail.com>
First post2012-10-06 06:05 +0000
Last post2012-10-06 06:05 +0000
Articles 1 — 1 participant

Back to article view | Back to comp.soft-sys.math.mathematica

This discussion starts older than the indexed window; earlier articles aren't shown. The article labeled Started by below is the oldest one visible, not the original post.


Contents

  Re: Animations in Graphs Bob Hanlon <hanlonr357@gmail.com> - 2012-10-06 06:05 +0000

#11961 — Re: Animations in Graphs

FromBob Hanlon <hanlonr357@gmail.com>
Date2012-10-06 06:05 +0000
SubjectRe: Animations in Graphs
Message-ID<k4ohmd$i5v$1@smc.vnet.net>
myR = Table[r, {r, 0, 1, .1}];

u[r_, \[Theta]_] = 1/(2*Pi)*((1 - r^2)/
     (1 - 2*r*Cos[\[Theta]] + r^2));

Plot[Evaluate[
  Tooltip[u[#, \[Theta]], #] & /@ myR],
 {\[Theta], -Pi/2, Pi/2},
 PlotRange -> {0, 3.25},
 AspectRatio -> 2/3,
 Frame -> True,
 Axes -> False]

Plot3D[u[r, \[Theta]],
 {\[Theta], -Pi/2, Pi/2},
 {r, 0, 1},
 PlotRange -> {0, 4},
 AspectRatio -> 2/3,
 ClippingStyle -> None]

Animate[
 Plot[u[r, \[Theta]], {\[Theta], -Pi/2, Pi/2},
  PlotRange -> {0, 3.25},
  GridLines -> Automatic,
  Frame -> True,
  PlotStyle -> {Thick, Red}],
 {r, 0, 1, 0.1},
 AnimationRunning -> False]

Manipulate[
 Plot[u[r, \[Theta]], {\[Theta], -Pi/2, Pi/2},
  PlotRange -> {0, 3.25},
  GridLines -> Automatic,
  Frame -> True,
  PlotStyle -> {Thick, Red}],
 {r, 0, 1, 0.01, Appearance -> "Labeled"}]


Bob Hanlon


On Fri, Oct 5, 2012 at 2:50 AM,  <psudharaka@gmail.com> wrote:
> Hi everyone,
>
> I produced the following graph but it wont animate.
>
> MyR = Table[r, {r, 0, 1, .1}];
>
> u[\[Theta]_] = 1/(2*Pi)*((1 - r^2)/(1 - 2*r*Cos[\[Theta]] + r^2));
> Plot[u[MyR, \[Theta]], {\[Theta], -Pi/2, Pi/2},
> PlotRange -> {0, 3.25}, PlotStyle -> {Red}, AspectRatio -> 2/3]
>
>
> This following code doesn't produce any errors or Mathematica complaining but nothing happens when I hit play.
>
> Animate[Plot[u[\[Theta]], {\[Theta], -Pi/2, Pi/2}, PlotRange -> {0, 3.25}, GridLines -> Automatic, Frame -> True, PlotStyle -> {Thick, Red}], {r, 0, 1, 0.1}, AnimationRunning -> False]
>
> Thank you and your help is much appreciated.
>

[toc] | [standalone]


Back to top | Article view | comp.soft-sys.math.mathematica


csiph-web