Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #6870 > unrolled thread

Re: Ploting a transformation of a set

Started byBob Hanlon <hanlonr357@gmail.com>
First post2011-12-01 11:01 +0000
Last post2011-12-01 11:01 +0000
Articles 1 — 1 participant

Back to article view | Back to comp.soft-sys.math.mathematica

This discussion starts older than the indexed window; earlier articles aren't shown. The article labeled Started by below is the oldest one visible, not the original post.


Contents

  Re: Ploting a transformation of a set Bob Hanlon <hanlonr357@gmail.com> - 2011-12-01 11:01 +0000

#6870 — Re: Ploting a transformation of a set

FromBob Hanlon <hanlonr357@gmail.com>
Date2011-12-01 11:01 +0000
SubjectRe: Ploting a transformation of a set
Message-ID<jb7mr0$gep$1@smc.vnet.net>
t = (x + y < 2 && 0 < x < 2 && 0 < y < 2) /.
   Solve[{xp == Sqrt[x + y/2], yp == Sqrt[y + x/2]},
     {x, y}][[1]] // Simplify

xp^2 + yp^2 < 3 && 0 < 2*xp^2 - yp^2 < 3 && -3 < xp^2 - 2*yp^2 < 0

Manipulate[
 Module[{
   aps = AbsolutePointSize[4],
   ap = (Appearance -> "Labeled")},
  Row[{
    RegionPlot[x + y < 2 && 0 < x < 2 && 0 < y < 2,
     {x, 0, 2}, {y, 0, 2},
     ImageSize -> 200,
     Epilog -> {Red, aps, Point[{h, v}]}],
    RegionPlot[t, {xp, 0, 2}, {yp, 0, 2},
     ImageSize -> 200,
     Epilog -> {Red, aps,
       Point[{Sqrt[h + v/2], Sqrt[v + h/2]}]}]}]],
 {{h, .5, "x"}, 0, 2, .01, ap},
 {{v, .5, "y"}, 0, 2, .01, ap}]


Bob Hanlon

On Wed, Nov 30, 2011 at 3:19 AM, Justin <justin.valasek@gmail.com> wrote:
> Hello,
> I would like to plot the following transformation of the set {x,y; x+y<2 & x>0 & y> 0} => {(x+.5y)^.5, (y+.5x)^.5}.
> Is there any way to do this in mathematica?
> thanks
>

[toc] | [standalone]


Back to top | Article view | comp.soft-sys.math.mathematica


csiph-web