Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #6870

Re: Ploting a transformation of a set

From Bob Hanlon <hanlonr357@gmail.com>
Newsgroups comp.soft-sys.math.mathematica
Subject Re: Ploting a transformation of a set
Date 2011-12-01 11:01 +0000
Organization Steven M. Christensen and Associates, Inc and MathTensor, Inc.
Message-ID <jb7mr0$gep$1@smc.vnet.net> (permalink)
References <201111300819.DAA17061@smc.vnet.net>

Show all headers | View raw


t = (x + y < 2 && 0 < x < 2 && 0 < y < 2) /.
   Solve[{xp == Sqrt[x + y/2], yp == Sqrt[y + x/2]},
     {x, y}][[1]] // Simplify

xp^2 + yp^2 < 3 && 0 < 2*xp^2 - yp^2 < 3 && -3 < xp^2 - 2*yp^2 < 0

Manipulate[
 Module[{
   aps = AbsolutePointSize[4],
   ap = (Appearance -> "Labeled")},
  Row[{
    RegionPlot[x + y < 2 && 0 < x < 2 && 0 < y < 2,
     {x, 0, 2}, {y, 0, 2},
     ImageSize -> 200,
     Epilog -> {Red, aps, Point[{h, v}]}],
    RegionPlot[t, {xp, 0, 2}, {yp, 0, 2},
     ImageSize -> 200,
     Epilog -> {Red, aps,
       Point[{Sqrt[h + v/2], Sqrt[v + h/2]}]}]}]],
 {{h, .5, "x"}, 0, 2, .01, ap},
 {{v, .5, "y"}, 0, 2, .01, ap}]


Bob Hanlon

On Wed, Nov 30, 2011 at 3:19 AM, Justin <justin.valasek@gmail.com> wrote:
> Hello,
> I would like to plot the following transformation of the set {x,y; x+y<2 & x>0 & y> 0} => {(x+.5y)^.5, (y+.5x)^.5}.
> Is there any way to do this in mathematica?
> thanks
>

Back to comp.soft-sys.math.mathematica | Previous | Next | Find similar | Unroll thread


Thread

Re: Ploting a transformation of a set Bob Hanlon <hanlonr357@gmail.com> - 2011-12-01 11:01 +0000

csiph-web