Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #14781

Re: visualizing a maximum in the intersection between two surfaces

From Bob Hanlon <hanlonr357@gmail.com>
Newsgroups comp.soft-sys.math.mathematica
Subject Re: visualizing a maximum in the intersection between two surfaces
Date 2013-06-09 08:26 +0000
Message-ID <kp1e6p$80d$1@smc.vnet.net> (permalink)
References <20130608063415.570076A22@smc.vnet.net>
Organization Time-Warner Telecom

Show all headers | View raw


ParametricPlot3D[
 {x, 1 - x, x (1 - x)},
 {x, 0, 1},
 Exclusions -> {x == 0.5},
 ExclusionsStyle ->
  Directive[Red, AbsoluteThickness[5]],
 AxesLabel ->
  (Style[#, 14, Bold] & /@
    {"x", "y", "x y"})]



Manipulate[
 Column[{
   ParametricPlot3D[
    {x, 1 - x, x (1 - x)},
    {x, 0, 1},
    Exclusions -> {x == xv},
    ExclusionsStyle ->
     Directive[Red, AbsoluteThickness[5]],
    AxesLabel ->
     (Style[#, 14, Bold] & /@
       {"x", " y", "x y "}),
    ImageSize -> 400], ,
   StringForm[
    "x = ``, y = ``, z = x y = ``",
    Round[xv, 1/100] // N,
    Round[1 - xv, 1/100] // N,
    Round[xv (1 - xv), 1/1000] // N]}],
 {{xv, .5, "x"}, 0, 1, 0.01,
  Appearance -> "Labeled"}]



Bob Hanlon


On Sat, Jun 8, 2013 at 2:34 AM, <dusko.cakara@gmail.com> wrote:

> Hello,
> can somebody please help:
> I want to visualize that for x+y=1, maximum x*y occurs when y=0.5 and
> x=0.5.
>
> Graphically, this can be visualized as the maximum of the projection curve
> of the x+y=1 line in the x-y plane, at the x*y surface. Equivalently, we
> can look for the maximum in the intersection curve between the surface x*y
> and the surface peripendicular to the x-y plane with the base x+y=1.
>
> Can I plot this in a simple manner?
>
> Thanks in advance!
> Dusko
>
>

Back to comp.soft-sys.math.mathematica | Previous | Next | Find similar | Unroll thread


Thread

Re: visualizing a maximum in the intersection between two surfaces Bob Hanlon <hanlonr357@gmail.com> - 2013-06-09 08:26 +0000

csiph-web