Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #13015

Re: PolynomialQuotient slow

From danl@wolfram.com
Newsgroups comp.soft-sys.math.mathematica
Subject Re: PolynomialQuotient slow
Date 2013-01-03 02:14 +0000
Message-ID <kc2pi2$md9$1@smc.vnet.net> (permalink)
References <kbtbip$cph$1@smc.vnet.net>
Organization Time-Warner Telecom

Show all headers | View raw


On Monday, December 31, 2012 6:45:13 PM UTC-6, Roman Pearce wrote:
> Something seems wrong here with the performance of PolynomialQuotient.  Is there blowup because the leading coefficient in x is a polynomial?  Also it seems slower in Mathematica 9 versus v8.
>
>
>
> d = 5
>
> f = Expand[ ((1+x)*(1+y)*(1+z))^d + 1 ];
>
> g = Expand[ ((1-x)*(1-y)*(1-z))^d + 1 ];
>
> AbsoluteTiming[ p = Expand[ f g ]; ]
>
> AbsoluteTiming[ q = PolynomialQuotient[p, f, x]; ]
>
> AbsoluteTiming[ P = Factor[ p ]; ]
>
>
>
> What is the preferred method for (exact) division of polynomials?  On this example I tried Cancel[ p/f ] and it works fine, but on other problems it is faster to use PolynomialQuotient.  Suggestions?

Hi Roman,

Yes, PolynomialQuotient is slow. It is, as you suspected, intrinsically "univariate" and thus does not work in a fraction-free manner when coefficients are themselves polynomials.

Here are some possibilities for improved speed.

(1) Use PolynomialReduce (in the sense of computing Groebner bases).

(2) Use PolynomialMod, as that seems better able to find a remainder quickly. Then subtract that from the dividend and Together the result over the divisor. If you know the division is exact to begin (as in this example) with you can skip the PolynomialMod step.

(3) Use a certain (undocumented) internal function.

Here are the three approaches.

In[51]:= AbsoluteTiming[{q2, r} =
  PolynomialReduce[p, f, Variables[{p, f}]]; q2 = First[q2];]

Out[51]= {0.052611, Null}

In[54]:= AbsoluteTiming[r = PolynomialMod[p, f];
 q3 = Together[(p - r)/f];]

Out[54]= {0.086507, Null}

In[59]:= AbsoluteTiming[q4 = Algebra`IPExactQuotient[p, f];]

Out[59]= {0.013560, Null}

In[69]:= Together[q] === q2 === q3 === q4

Out[69]= True

Regards,
Daniel

Back to comp.soft-sys.math.mathematica | Previous | Next — Previous in thread | Next in thread | Find similar | Unroll thread


Thread

PolynomialQuotient slow Roman Pearce <rpearcea@gmail.com> - 2013-01-01 00:45 +0000
  Re: PolynomialQuotient slow danl@wolfram.com - 2013-01-03 02:14 +0000
    Re: PolynomialQuotient slow Roman Pearce <rpearcea@gmail.com> - 2013-01-05 07:17 +0000
      Re: PolynomialQuotient slow danl@wolfram.com - 2013-01-07 05:35 +0000

csiph-web