Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #5433

Re: Re: simplification

From DrMajorBob <btreat1@austin.rr.com>
Newsgroups comp.soft-sys.math.mathematica
Subject Re: Re: simplification
Date 2011-10-06 08:30 +0000
Organization Steven M. Christensen and Associates, Inc and MathTensor, Inc.
Message-ID <j6jp00$mb1$1@smc.vnet.net> (permalink)
References <j6e693$kef$1@smc.vnet.net> <201110050801.EAA07025@smc.vnet.net>

Show all headers | View raw


This might be a trifle easier to understand:

o1 = 1 + Sqrt[15 + 2*Sqrt[35] + 2*Sqrt[6*(6 + Sqrt[35])]];
poly = RootReduce[o1][[1]]
coefficients = Abs@CoefficientList[poly[x], x];
divisors = Union@Flatten@Divisors@Abs@CoefficientList[poly[x], x]
ext = Flatten@{1, Sqrt@Select[divisors, PrimeQ]}
nullVector = FindIntegerNullVector[Prepend[ext, -o1]]
o2 = ext.Rest@Normalize[nullVector, First]

1024 + 3584 #1 + 640 #1^2 - 1984 #1^3 - 48 #1^4 + 304 #1^5 -
   32 #1^6 - 8 #1^7 + #1^8 &

{1, 2, 3, 4, 5, 6, 7, 8, 10, 12, 14, 16, 19, 20, 24, 28, 31, 32, 38, \
40, 48, 56, 62, 64, 76, 80, 112, 124, 128, 152, 160, 224, 248, 256, \
304, 320, 448, 496, 512, 640, 896, 992, 1024, 1792, 1984, 3584}

{1, Sqrt[2], Sqrt[3], Sqrt[5], Sqrt[7], Sqrt[19], Sqrt[31]}

{1, 1, 0, 1, 1, 1, 0, 0}

1 + Sqrt[3] + Sqrt[5] + Sqrt[7]

Bobby

On Wed, 05 Oct 2011 03:01:50 -0500, Peter Pein <petsie@dordos.net> wrote:

> Am 04.10.2011 07:40, schrieb dimitris:
>> Hello.
>>
>> Let
>>
>> o1 = 1 + Sqrt[15 + 2*Sqrt[35] + 2*Sqrt[6*(6 + Sqrt[35])]];
>> o2 = 1 + Sqrt[3] + Sqrt[5] + Sqrt[7];
>>
>> o1 is equal to o2.
>>
>> o1 == o2 // FullSimplify
>> True
>>
>> The question is how to make Mathematica to simplify o1 to o2.
>>
>> Thanks
>> Dimitris
>>
>
> With a lot of luck:
>
> In[1]:= o1 = 1 + Sqrt[15 + 2*Sqrt[35] + 2*Sqrt[6*(6 + Sqrt[35])]];
>   ext = Block[{x, poly = RootReduce[o1][[1]]},
>    Sqrt[Cases[Union @@ Divisors[Abs[CoefficientList[poly[x], x]]],
>      1 | _?PrimeQ, 1]]]
>   o2 = ((Rest[#1] / First[#1]) . ext & )[
>         FindIntegerNullVector[Prepend[ext, -o1]]]
>
> Out[3]= {1, Sqrt[2], Sqrt[3], Sqrt[5], Sqrt[7], Sqrt[19], Sqrt[31]}
>
> Out[4]= 1 + Sqrt[3] + Sqrt[5] + Sqrt[7]
>
> :-)
>


-- 
DrMajorBob@yahoo.com

Back to comp.soft-sys.math.mathematica | Previous | Next — Previous in thread | Next in thread | Find similar | Unroll thread


Thread

simplification dimitris <dimmechan@yahoo.com> - 2011-10-04 05:40 +0000
  Re: simplification "Dr. Wolfgang Hintze" <weh@snafu.de> - 2011-10-05 08:01 +0000
  Re: simplification Peter Pein <petsie@dordos.net> - 2011-10-05 08:10 +0000
    Re: simplification "Dr. Wolfgang Hintze" <weh@snafu.de> - 2011-10-06 08:42 +0000
  Re:  Re: simplification DrMajorBob <btreat1@austin.rr.com> - 2011-10-06 08:30 +0000
  Re:  Re: simplification Andrzej Kozlowski <akoz@mimuw.edu.pl> - 2011-10-07 08:54 +0000
  Re:  Re: simplification Andrzej Kozlowski <akoz@mimuw.edu.pl> - 2011-10-07 09:03 +0000
  Re:  Re: simplification Andrzej Kozlowski <akoz@mimuw.edu.pl> - 2011-10-07 09:06 +0000
  Re: find two numbers a,b, such that a+b=5432 & LCM[a,b]=223020 Andrzej Kozlowski <akoz@mimuw.edu.pl> - 2011-10-16 20:47 +0000
  Re: find two numbers a,b, such that a+b=5432 & LCM[a,b]=223020 "Harvey P. Dale" <hpd1@nyu.edu> - 2011-10-17 12:10 +0000
  Re: find two numbers a,b, such that a+b=5432 & LCM[a,b]=223020 Andrzej Kozlowski <akoz@mimuw.edu.pl> - 2011-10-17 12:12 +0000
  Re: find two numbers a,b, such that a+b=5432 & LCM[a,b]=223020 Andrzej Kozlowski <akoz@mimuw.edu.pl> - 2011-10-18 11:40 +0000

csiph-web