Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]

Groups > comp.lang.c > #59671

Re: Does each core of 8-core Intel processor has an independent floating X87 unit?

From Melzzzzz <mel@zzzzz.com>
Newsgroups comp.lang.c
Subject Re: Does each core of 8-core Intel processor has an independent floating X87 unit?
Date 2015-04-06 03:36 +0200
Organization albasani.net
Message-ID <20150406033642.25b7ee95@maxa-pc> (permalink)
References <0c864744-32bf-4ce9-8b2e-f2a842fec7bb@googlegroups.com> <mfrjl7$k2k$1@dont-email.me> <20150405173522.3ab6e642@maxa-pc> <mfsggu$ulb$1@dont-email.me>

Show all headers | View raw

On Mon, 06 Apr 2015 01:30:29 +0200
jacobnavia <jacob@jacob.remcomp.fr> wrote:

> Le 05/04/2015 17:35, Melzzzzz a écrit :
> > On Sun, 05 Apr 2015 17:17:42 +0200
> > Noob <root@127.0.0.1> wrote:
> >
> >>
> >> And x87 is obsolete.
> >>
> >
> > Who said that?
> >
> lcc-win was generating a fsin instruction to calculate the sin(x)
> using the x87
> 
> I was completely ASTONISHED that gcc was much faster. They had an 
> optimized sin routine in SSE and their routine was faster than a
> SINGLE FPU instruction...
> 
> Intel hasn't upgraded the x87 since at least 10-15 years...
> 
> I still generate fsin though...

I have AVX/AVX2 routines to calculate sin/cos/tan in parallel and it is
twice as fast as gcc's and x87. for *single* calculation of 4 doubles ;)
I have posted ti here.
It is verabtim translation of what cephes library does, I hope someone 
find it useful :

[bmaxa@maxa-pc tasks]$ ./fptanmain 
-0.782455544155212 x87 tangent time 0.373150
-0.782455544155212 x87 tangent time 0.378290
-0.782455544155212 clib tan time 0.328371
-0.782455544155212 cephes tan time 0.354883
-0.782455544155212 tan_pd time 0.202565
0.616233456829857 x87 sine time 0.304618
0.616233456829857 clib sin time 0.271159
0.616233456829857 cephes sin time 0.308971
0.616233456829857 sin_pd time 0.155133
-0.787563538188206 x87 cosine time 0.304308
-0.787563538188206 clib cos time 0.281714
-0.787563538188206 cephes cos time 0.313464
-0.787563538188206 cos_pd time 0.234667
0.616233456829857 -0.787563538188206 x87 sincos time 0.354192
0.616233456829857 -0.787563538188206 clib sincos time 0.553157
0.616233456829857 -0.787563538188206 sincos_pd time 0.184800

source:

[bmaxa@maxa-pc tasks]$ cat fptan.asm
format elf64
define AVX2 1

macro polevl p1,p2,p3 {
	local .L0
	; %1 = ymm value,%2 = addr coef array , %3 = N
	mov rbx,p2
	lea rcx,[rbx+8*p3]
	vbroadcastsd ymm15,[rbx]
.L0:
	add rbx,8
if AVX2
	vbroadcastsd ymm14,[rbx]
	vfmadd213pd ymm15,p1,ymm14
else
	vmulpd ymm15,ymm15,p1
	vbroadcastsd ymm14,[rbx]
	vaddpd ymm15,ymm15,ymm14
end if
	cmp rbx,rcx
	jl .L0
}

macro p1evl p1,p2,p3 {
	local .L0
	; %1 = ymm value,%2 = addr coef array , %3 = N
	mov rbx,p2
	lea rcx,[rbx+8*(p3-1)]
	vbroadcastsd ymm15,[rbx]
	vaddpd ymm15,ymm15,p1
.L0:
	add rbx,8
if AVX2
	vbroadcastsd ymm14,[rbx]
	vfmadd213pd ymm15,p1,ymm14
else
	vmulpd ymm15,ymm15,p1
	vbroadcastsd ymm14,[rbx]
	vaddpd ymm15,ymm15,ymm14
end if
	cmp rbx,rcx
	jl .L0
}

section '.text' executable

public tangent
public sine
public cosine
public sin_pd
public cos_pd
public tan_pd
public x87sincos
public sincos_pd

tangent:
	sub rsp,8
	vmovsd [rsp],xmm0
	fld qword[rsp]
	fptan
	fstp st0
	fstp qword[rsp]
	vmovsd xmm0,[rsp]
	add rsp,8
	ret

sine:
	sub rsp,8
	vmovsd [rsp],xmm0
	fld qword[rsp]
	fsin
	fstp qword[rsp]
	vmovsd xmm0,[rsp]
	add rsp,8
	ret
cosine:
	sub rsp,8
	vmovsd [rsp],xmm0
	fld qword[rsp]
	fcos
	fstp qword[rsp]
	vmovsd xmm0,[rsp]
	add rsp,8
	ret
x87sincos:
	sub rsp,8
	vmovsd [rsp],xmm0
	fld qword[rsp]
	fsincos
	fstp qword[rsi]
	fstp qword[rdi]
	add rsp,8
	ret
; ymm0 -> x
sin_pd:
	push rbx
	vmovapd ymm1,ymm0
	vmovapd ymm2,[sign_mask]
	vandnpd ymm0,ymm2,ymm0 ; make positive x
	vandpd ymm1,ymm1,[sign_mask] ; save sign bit
	
	vbroadcastsd ymm2,[O4PI]
	vmulpd ymm3,ymm0,ymm2 ; 
	vroundpd ymm3,ymm3,3 ; truncate y

	vmulpd ymm2,ymm3,[OD16]
	vroundpd ymm2,ymm2,3
	
;	vmulpd ymm2,ymm2,[S16]
;	vsubpd ymm2,ymm3,ymm2

	vfnmadd132pd ymm2,ymm3,[S16]
	
	vcvttpd2dq xmm2,ymm2 ; j

	vpand xmm4,xmm2,[mask_1]
	vpaddd xmm2,xmm2,xmm4 ; j += 1
	vcvtdq2pd ymm4,xmm4
	vaddpd ymm3,ymm3,ymm4 ; y += 1.0
	
	vpand xmm4,xmm2,[mask_4]
	vpslld xmm4,xmm4,29 ; move mask to highest position
if AVX2 ; just example, too lazy to repeat for other functions ;)
	vpmovzxdq ymm4,xmm4
	vpsllq ymm4,ymm4,32
else
	vpmovzxdq xmm5,xmm4
	vpsllq xmm5,xmm5,32
	vpsrldq xmm4,xmm4,8
	vpmovzxdq xmm6,xmm4
	vpsllq xmm6,xmm6,32
	vmovapd xmm4,xmm5
	vinsertf128 ymm4,ymm4,xmm6,1
end if
	vxorpd ymm1,ymm1,ymm4 ; invert sign

	vpand xmm4,xmm2,[mask_3]
	vpcmpeqd xmm4,xmm4,[mask_0] 
if AVX2
	vpmovsxdq ymm4,xmm4
else
	vpmovsxdq xmm5,xmm4
	vpsrldq xmm4,xmm4,8
	vpmovsxdq xmm6,xmm4
	vmovapd xmm4,xmm5
	vinsertf128 ymm4,ymm4,xmm6,1 ; selection mask 
end if

; Extended precision modular arithmetic	
;	vmulpd ymm5,ymm3,[DP1]
;	vmulpd ymm6,ymm3,[DP2]
;	vmulpd ymm7,ymm3,[DP3]
;	vsubpd ymm0,ymm0,ymm5
;	vsubpd ymm0,ymm0,ymm6
;	vsubpd ymm0,ymm0,ymm7

	vfnmadd231pd ymm0,ymm3,[DP1]
	vfnmadd231pd ymm0,ymm3,[DP2]
	vfnmadd231pd ymm0,ymm3,[DP3]

	vmulpd ymm5,ymm0,ymm0 ; x^2

	; first	
	polevl ymm5,sincof,5
	vmulpd ymm15,ymm15,ymm5
;	vmulpd ymm15,ymm15,ymm0
;	vaddpd ymm6,ymm15,ymm0 ; y1
	
	vfmadd132pd ymm15,ymm0,ymm0
	vmovapd ymm6,ymm15

	; second
	polevl ymm5,coscof,5
	vmulpd ymm15,ymm15,ymm5
	vmulpd ymm15,ymm15,ymm5
;	vmulpd ymm7,ymm5,[OD2]
;	vsubpd ymm7,ymm15,ymm7

	vfnmadd231pd ymm15,ymm5,[OD2]
	vmovapd ymm7,ymm15

	vaddpd ymm7,ymm7,[one]; y2

	; combine
	vandpd ymm6,ymm4,ymm6
	vandnpd ymm7,ymm4,ymm7
	vaddpd ymm0,ymm6,ymm7

	vxorpd ymm0,ymm0,ymm1
	pop rbx
	ret
; ymm0 -> x
cos_pd:
	push rbx
	vmovapd ymm1,ymm0
	vmovapd ymm2,[sign_mask]
	vandnpd ymm0,ymm2,ymm0 ; make positive x
	vandpd ymm1,ymm1,[sign_mask] ; save sign bit
	
	vbroadcastsd ymm2,[O4PI]
	vmulpd ymm3,ymm0,ymm2 ; 
	vroundpd ymm3,ymm3,3 ; truncate y

	vmulpd ymm2,ymm3,[OD16]
	vroundpd ymm2,ymm2,3
	vmulpd ymm2,ymm2,[S16]
	vsubpd ymm2,ymm3,ymm2
	vcvttpd2dq xmm2,ymm2 ; j

	vpand xmm4,xmm2,[mask_1]
	vpaddd xmm2,xmm2,xmm4 ; j += 1
	vcvtdq2pd ymm4,xmm4
	vaddpd ymm3,ymm3,ymm4 ; y += 1.0
	
	vpand xmm4,xmm2,[mask_4]
	vpslld xmm4,xmm4,29 ; move mask to highest position
	vpmovzxdq xmm5,xmm4
	vpsllq xmm5,xmm5,32
	vpsrldq xmm4,xmm4,8
	vpmovzxdq xmm6,xmm4
	vpsllq xmm6,xmm6,32
	vmovapd xmm4,xmm5
	vinsertf128 ymm4,ymm4,xmm6,1
	vxorpd ymm1,ymm1,ymm4 ; invert sign

	vpand xmm4,xmm2,[mask_3]
	vpcmpeqd xmm4,xmm4,[mask_0] 
	vpmovsxdq xmm5,xmm4
	vpsrldq xmm4,xmm4,8
	vpmovsxdq xmm6,xmm4
	vmovapd xmm4,xmm5
	vinsertf128 ymm4,ymm4,xmm6,1 ; selection mask 

	; Extended precision modular arithmetic	
	vmulpd ymm5,ymm3,[DP1]
	vmulpd ymm6,ymm3,[DP2]
	vmulpd ymm7,ymm3,[DP3]
	vsubpd ymm0,ymm0,ymm5
	vsubpd ymm0,ymm0,ymm6
	vsubpd ymm0,ymm0,ymm7

	vmulpd ymm5,ymm0,ymm0 ; x^2

	; first	
	polevl ymm5,sincof,5
	vmulpd ymm15,ymm15,ymm5
	vmulpd ymm15,ymm15,ymm0
	vaddpd ymm6,ymm15,ymm0 ; y1
	
	; second
	polevl ymm5,coscof,5
	vmulpd ymm15,ymm15,ymm5
	vmulpd ymm15,ymm15,ymm5
	vmulpd ymm7,ymm5,[OD2]
	vsubpd ymm7,ymm15,ymm7
	vaddpd ymm7,ymm7,[one]; y2

	; combine
	vandnpd ymm6,ymm4,ymm6
	vandpd ymm7,ymm4,ymm7
	vaddpd ymm0,ymm6,ymm7

	vxorpd ymm0,ymm0,ymm1
	pop rbx
	ret
	
; ymm0 -> x
sincos_pd:
	push rbx
	vmovapd ymm1,ymm0
	vmovapd ymm2,[sign_mask]
	vandnpd ymm0,ymm2,ymm0 ; make positive x
	vandpd ymm1,ymm1,[sign_mask] ; save sign bit
	
	vbroadcastsd ymm2,[O4PI]
	vmulpd ymm3,ymm0,ymm2 ; 
	vroundpd ymm3,ymm3,3 ; truncate y

	vmulpd ymm2,ymm3,[OD16]
	vroundpd ymm2,ymm2,3
	vmulpd ymm2,ymm2,[S16]
	vsubpd ymm2,ymm3,ymm2
	vcvttpd2dq xmm2,ymm2 ; j

	vpand xmm4,xmm2,[mask_1]
	vpaddd xmm2,xmm2,xmm4 ; j += 1
	vcvtdq2pd ymm4,xmm4
	vaddpd ymm3,ymm3,ymm4 ; y += 1.0
	
	vpand xmm4,xmm2,[mask_4]
	vpslld xmm4,xmm4,29 ; move mask to highest position
	vpmovzxdq xmm5,xmm4
	vpsllq xmm5,xmm5,32
	vpsrldq xmm4,xmm4,8
	vpmovzxdq xmm6,xmm4
	vpsllq xmm6,xmm6,32
	vmovapd xmm4,xmm5
	vinsertf128 ymm4,ymm4,xmm6,1
	vxorpd ymm1,ymm1,ymm4 ; invert sign

	vpand xmm4,xmm2,[mask_3]
	vpcmpeqd xmm4,xmm4,[mask_0] 
	vpmovsxdq xmm5,xmm4
	vpsrldq xmm4,xmm4,8
	vpmovsxdq xmm6,xmm4
	vmovapd xmm4,xmm5
	vinsertf128 ymm4,ymm4,xmm6,1 ; selection mask 

	; Extended precision modular arithmetic	
	vmulpd ymm5,ymm3,[DP1]
	vmulpd ymm6,ymm3,[DP2]
	vmulpd ymm7,ymm3,[DP3]
	vsubpd ymm0,ymm0,ymm5
	vsubpd ymm0,ymm0,ymm6
	vsubpd ymm0,ymm0,ymm7

	vmulpd ymm5,ymm0,ymm0 ; x^2

	; first	
	polevl ymm5,sincof,5
	vmulpd ymm15,ymm15,ymm5
	vmulpd ymm15,ymm15,ymm0
	vaddpd ymm6,ymm15,ymm0 ; y1
	
	; second
	polevl ymm5,coscof,5
	vmulpd ymm15,ymm15,ymm5
	vmulpd ymm15,ymm15,ymm5
	vmulpd ymm7,ymm5,[OD2]
	vsubpd ymm7,ymm15,ymm7
	vaddpd ymm7,ymm7,[one]; y2

	; combine sin
	vandpd ymm8,ymm4,ymm6
	vandnpd ymm9,ymm4,ymm7
	vaddpd ymm0,ymm8,ymm9

	vxorpd ymm0,ymm0,ymm1
	vmovupd [rdi],ymm0

	; combine cos
	vandnpd ymm6,ymm4,ymm6
	vandpd ymm7,ymm4,ymm7
	vaddpd ymm0,ymm6,ymm7

	vxorpd ymm0,ymm0,ymm1
	vmovupd [rsi],ymm0
	
	pop rbx
	ret
tan_pd:
	push rbx
	vmovapd ymm1,ymm0
	vmovapd ymm2,[sign_mask]
	vandnpd ymm0,ymm2,ymm0 ; make positive x
	vandpd ymm1,ymm1,[sign_mask] ; save sign bit
	
	vbroadcastsd ymm2,[O4PI]
	vmulpd ymm3,ymm0,ymm2 ; 
	vroundpd ymm3,ymm3,3 ; truncate y

	vmulpd ymm2,ymm3,[OD16]
	vroundpd ymm2,ymm2,3
	vmulpd ymm2,ymm2,[S16]
	vsubpd ymm2,ymm3,ymm2
	vcvttpd2dq xmm2,ymm2 ; j

	vpand xmm4,xmm2,[mask_1]
	vpaddd xmm2,xmm2,xmm4 ; j += 1
	vcvtdq2pd ymm4,xmm4
	vaddpd ymm3,ymm3,ymm4 ; y += 1.0
	
	vpand xmm4,xmm2,[mask_2]
	vpcmpeqd xmm4,xmm4,[mask_0] 
	vpmovsxdq xmm5,xmm4
	vpsrldq xmm4,xmm4,8
	vpmovsxdq xmm6,xmm4
	vmovapd xmm4,xmm5
	vinsertf128 ymm4,ymm4,xmm6,1 ; selection mask 2

	; Extended precision modular arithmetic	
	vmulpd ymm5,ymm3,[DP1]
	vmulpd ymm6,ymm3,[DP2]
	vmulpd ymm7,ymm3,[DP3]
	vsubpd ymm0,ymm0,ymm5
	vsubpd ymm0,ymm0,ymm6
	vsubpd ymm0,ymm0,ymm7

	vmulpd ymm5,ymm0,ymm0 ; x^2

	vcmpnlepd ymm6,ymm5,[prec] ; selection mask 1
	
	;calculate polynom
	polevl ymm5,P,2
	vmovapd ymm13,ymm15
	p1evl ymm5,Q,4
	vdivpd ymm13,ymm13,ymm15
	vmulpd ymm13,ymm13,ymm5
	vmulpd ymm13,ymm13,ymm0
	vaddpd ymm13,ymm13,ymm0
	
	vandpd ymm13,ymm6,ymm13
	vandnpd ymm0,ymm6,ymm0 ; select according to mask 1
	vaddpd ymm0,ymm13,ymm0
	
	vmovapd ymm6,[mone]
	vdivpd ymm7,ymm6,ymm0
	
	vandpd ymm0,ymm4,ymm0
	vandnpd ymm7,ymm4,ymm7 ; select according to mask 2
	vaddpd ymm0,ymm0,ymm7
	
	vxorpd ymm0,ymm0,ymm1 ; invert sign
	pop rbx
	ret

section '.data' writeable align 32
sincof dq \
	1.58962301576546568060E-10,\
	-2.50507477628578072866E-8,\
	2.75573136213857245213E-6,\
	-1.98412698295895385996E-4,\
	8.33333333332211858878E-3,\
	-1.66666666666666307295E-1
coscof dq \
	-1.13585365213876817300E-11,\
	2.08757008419747316778E-9,\
	-2.75573141792967388112E-7,\
	2.48015872888517045348E-5,\
	-1.38888888888730564116E-3,\
	4.16666666666665929218E-2
P dq \
-1.30936939181383777646E4, \
 1.15351664838587416140E6, \
 -1.79565251976484877988E7 
Q dq \
 1.36812963470692954678E4, \
 -1.32089234440210967447E6,\
  2.50083801823357915839E7,\
  -5.38695755929454629881E7 
O4PI dq 1.273239544735162
align 32
DP1: times 4 dq   7.85398125648498535156E-1;
DP2: times 4 dq   3.77489470793079817668E-8;
DP3: times 4 dq   2.69515142907905952645E-15;
sign_mask: times 4 dq 0x8000000000000000
prec: times 4 dq 1.0e-14
one: times 4 dq 1.0
mone: times 4 dq -1.0
OD16: times 4 dq 0.0625
S16: times 4 dq 16.0
OD2: times 4 dq 0.5
mask_0: times 4 dd 0
mask_1: times 4 dd 1
mask_2: times 4 dd 2
mask_3: times 4 dd 3
mask_4: times 4 dd 4

Back to comp.lang.c | Previous | Next — Previous in thread | Next in thread | Find similar | Unroll thread

Thread

Does each core of 8-core Intel processor has an independent floating X87 unit? Weng Tianxiang <wtxwtx@gmail.com> - 2015-04-05 06:50 -0700
  Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Noob <root@127.0.0.1> - 2015-04-05 17:17 +0200
    Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Melzzzzz <mel@zzzzz.com> - 2015-04-05 17:35 +0200
      Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-05 11:21 -0500
        Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Melzzzzz <mel@zzzzz.com> - 2015-04-05 18:40 +0200
          Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-05 11:56 -0500
            Re: Does each core of 8-core Intel processor has an independent floating X87 unit? fir <profesor.fir@gmail.com> - 2015-04-05 10:08 -0700
              Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-05 13:17 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? David Brown <david.brown@hesbynett.no> - 2015-04-07 10:10 +0200
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-07 10:26 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? David Brown <david.brown@hesbynett.no> - 2015-04-07 23:40 +0200
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Bartc <bc@freeuk.com> - 2015-04-07 23:06 +0100
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? David Brown <david.brown@hesbynett.no> - 2015-04-08 01:23 +0200
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-07 23:15 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-07 20:16 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? David Brown <david.brown@hesbynett.no> - 2015-04-08 09:27 +0200
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-08 09:44 -0500
            Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Melzzzzz <mel@zzzzz.com> - 2015-04-05 19:37 +0200
              Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-05 18:50 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Robert Wessel <robertwessel2@yahoo.com> - 2015-04-05 22:29 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-05 23:09 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Robert Wessel <robertwessel2@yahoo.com> - 2015-04-06 01:54 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-06 07:44 -0500
              Re: Does each core of 8-core Intel processor has an independent floating X87 unit? David Brown <david.brown@hesbynett.no> - 2015-04-07 10:16 +0200
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Robert Wessel <robertwessel2@yahoo.com> - 2015-04-07 03:32 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? David Brown <david.brown@hesbynett.no> - 2015-04-07 12:48 +0200
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Richard Heathfield <rjh@cpax.org.uk> - 2015-04-07 11:57 +0100
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? David Brown <david.brown@hesbynett.no> - 2015-04-07 13:33 +0200
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Robert Wessel <robertwessel2@yahoo.com> - 2015-04-07 15:21 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? glen herrmannsfeldt <gah@ugcs.caltech.edu> - 2015-04-07 17:15 +0000
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Tim Prince <tprince@computer.org> - 2015-04-07 14:21 -0400
            Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Keith Thompson <kst-u@mib.org> - 2015-04-05 13:08 -0700
              Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-05 15:27 -0500
          Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Noob <root@127.0.0.1> - 2015-04-05 19:04 +0200
            Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Melzzzzz <mel@zzzzz.com> - 2015-04-05 19:38 +0200
              Re: Does each core of 8-core Intel processor has an independent floating X87 unit? fir <profesor.fir@gmail.com> - 2015-04-05 10:46 -0700
            Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Keith Thompson <kst-u@mib.org> - 2015-04-05 13:12 -0700
        Re: Does each core of 8-core Intel processor has an independent floating X87 unit? fir <profesor.fir@gmail.com> - 2015-04-05 09:51 -0700
          Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-05 12:18 -0500
      Re: Does each core of 8-core Intel processor has an independent floating X87 unit? jacobnavia <jacob@jacob.remcomp.fr> - 2015-04-06 01:30 +0200
        Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-05 19:27 -0500
          Re: Does each core of 8-core Intel processor has an independent floating X87 unit? christian.bau@cbau.wanadoo.co.uk - 2015-04-07 23:58 -0700
            Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-08 08:08 -0500
        Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Melzzzzz <mel@zzzzz.com> - 2015-04-06 03:36 +0200
        Re: Does each core of 8-core Intel processor has an independent floating X87 unit? David Brown <david.brown@hesbynett.no> - 2015-04-07 10:27 +0200
          Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-07 10:39 -0500
        Re: Does each core of 8-core Intel processor has an independent floating X87 unit? christian.bau@cbau.wanadoo.co.uk - 2015-04-07 23:47 -0700
    Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-05 11:04 -0500
      Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Melzzzzz <mel@zzzzz.com> - 2015-04-05 18:20 +0200
        Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-05 11:43 -0500
      Re: Does each core of 8-core Intel processor has an independent floating X87 unit? glen herrmannsfeldt <gah@ugcs.caltech.edu> - 2015-04-05 20:28 +0000
        Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Malcolm McLean <malcolm.mclean5@btinternet.com> - 2015-04-05 14:46 -0700
          Re: Does each core of 8-core Intel processor has an independent floating X87 unit? fir <profesor.fir@gmail.com> - 2015-04-05 15:01 -0700
    Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Keith Thompson <kst-u@mib.org> - 2015-04-05 13:17 -0700
  Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Paul <nospam@needed.com> - 2015-04-05 14:31 -0400
    Re: Does each core of 8-core Intel processor has an independent floating X87 unit? David Brown <david.brown@hesbynett.no> - 2015-04-07 11:01 +0200
  Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Robert Wessel <robertwessel2@yahoo.com> - 2015-04-05 22:34 -0500
    Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Weng Tianxiang <wtxwtx@gmail.com> - 2015-04-05 23:39 -0700
      Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Robert Wessel <robertwessel2@yahoo.com> - 2015-04-06 02:06 -0500
        Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-06 08:57 -0500
          Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Robert Wessel <robertwessel2@yahoo.com> - 2015-04-06 12:38 -0500
            Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-06 16:30 -0500
              Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Stephen Sprunk <stephen@sprunk.org> - 2015-04-06 17:10 -0500
                Re: Does each core of 8-core Intel processor has an independent floating   X87 unit? Ian Collins <ian-news@hotmail.com> - 2015-04-07 10:16 +1200
                Re: Does each core of 8-core Intel processor has an independent floating   X87 unit? Melzzzzz <mel@zzzzz.com> - 2015-04-07 02:23 +0200
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-06 17:36 -0500
              Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Robert Wessel <robertwessel2@yahoo.com> - 2015-04-06 17:41 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-06 20:09 -0500
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Richard Damon <Richard@Damon-Family.org> - 2015-04-06 22:44 -0400
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? David Brown <david.brown@hesbynett.no> - 2015-04-07 11:11 +0200
        Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Weng Tianxiang <wtxwtx@gmail.com> - 2015-04-06 08:04 -0700
          Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Robert Wessel <robertwessel2@yahoo.com> - 2015-04-06 12:43 -0500
          Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Paul <nospam@needed.com> - 2015-04-06 14:52 -0400
            Re: Does each core of 8-core Intel processor has an independent floating X87 unit? BGB <cr88192@hotmail.com> - 2015-04-06 17:09 -0500
      Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Paul <nospam@needed.com> - 2015-04-06 11:11 -0400
        Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Robert Wessel <robertwessel2@yahoo.com> - 2015-04-06 12:47 -0500
          Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Stephen Sprunk <stephen@sprunk.org> - 2015-04-06 17:15 -0500
            Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Robert Wessel <robertwessel2@yahoo.com> - 2015-04-07 03:41 -0500
              Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Ian Collins <ian-news@hotmail.com> - 2015-04-07 21:19 +1200
                Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Stephen Sprunk <stephen@sprunk.org> - 2015-04-07 10:37 -0500
                Re: Does each core of 8-core Intel processor has an independent floating   X87 unit? Tim Prince <tprince@computer.org> - 2015-04-07 12:13 -0400
                Re: Does each core of 8-core Intel processor has an independent floating   X87 unit? Stephen Sprunk <stephen@sprunk.org> - 2015-04-09 12:34 -0500
              Re: Does each core of 8-core Intel processor has an independent floating X87 unit? Stephen Sprunk <stephen@sprunk.org> - 2015-04-07 10:48 -0500

csiph-web