Groups > comp.sys.apple2.programmer > #3726 > unrolled thread

What is ProDOS Error Code 3?

Started by	Bill Chatfield <billchatfield1@gmail.com>
First post	2017-07-22 01:31 -0700
Last post	2017-08-04 23:28 -0700
Articles	20 on this page of 26 — 8 participants

Back to article view | Back to comp.sys.apple2.programmer

  What is ProDOS Error Code 3? Bill Chatfield <billchatfield1@gmail.com> - 2017-07-22 01:31 -0700
    Re: What is ProDOS Error Code 3? gids.rs@sasktel.net - 2017-07-22 06:17 -0700
      Re: What is ProDOS Error Code 3? Michael Pohoreski <michael.pohoreski@gmail.com> - 2017-07-22 15:03 -0700
        Re: What is ProDOS Error Code 3? gids.rs@sasktel.net - 2017-07-22 22:47 -0700
    What is ProDOS Error Code 3? Michael Pohoreski <michael.pohoreski@gmail.com> - 2017-07-22 13:42 -0700
      Re: What is ProDOS Error Code 3? Bill Chatfield <billchatfield1@gmail.com> - 2017-09-07 13:34 -0700
        Re: What is ProDOS Error Code 3? Bill Chatfield <billchatfield1@gmail.com> - 2017-09-07 13:49 -0700
    What is ProDOS Error Code 3? Michael Pohoreski <michael.pohoreski@gmail.com> - 2017-07-22 16:23 -0700
      Re: What is ProDOS Error Code 3? rhoem1@gmail.com - 2017-07-23 16:23 -0700
        Re: What is ProDOS Error Code 3? Michael J. Mahon <mjmahon@aol.com> - 2017-07-23 21:47 -0500
          Re: What is ProDOS Error Code 3? Nick Westgate <nick.westgate@gmail.com> - 2017-08-02 16:33 -0700
            Re: What is ProDOS Error Code 3? Bill Chatfield <billchatfield1@gmail.com> - 2017-08-04 23:27 -0700
              Re: What is ProDOS Error Code 3? Nick Westgate <nick.westgate@gmail.com> - 2017-08-04 23:49 -0700
                Re: What is ProDOS Error Code 3? Bill Chatfield <billchatfield1@gmail.com> - 2017-08-05 11:58 -0700
                  Re: What is ProDOS Error Code 3? James Davis <JPD.Enterprises@outlook.com> - 2017-08-06 12:56 -0700
                    Re: What is ProDOS Error Code 3? D Finnigan <dog_cow@macgui.com> - 2017-08-06 20:28 +0000
                      Re: What is ProDOS Error Code 3? James Davis <JPD.Enterprises@outlook.com> - 2017-08-06 14:11 -0700
                        Re: What is ProDOS Error Code 3? Bill Chatfield <billchatfield1@gmail.com> - 2017-08-06 20:31 -0700
                          Re: What is ProDOS Error Code 3? James Davis <JPD.Enterprises@outlook.com> - 2017-08-06 23:35 -0700
                            Re: What is ProDOS Error Code 3? Bill Chatfield <billchatfield1@gmail.com> - 2017-08-07 10:14 -0700
                              Re: What is ProDOS Error Code 3? James Davis <JPD.Enterprises@outlook.com> - 2017-08-07 12:02 -0700
                              Re: What is ProDOS Error Code 3? Michael Pohoreski <michael.pohoreski@gmail.com> - 2017-08-17 14:26 -0700
                                Re: What is ProDOS Error Code 3? gids.rs@sasktel.net - 2017-08-17 14:55 -0700
                                Re: What is ProDOS Error Code 3? James Davis <JPD.Enterprises@outlook.com> - 2017-08-18 18:20 -0700
      Re: What is ProDOS Error Code 3? Bill Chatfield <billchatfield1@gmail.com> - 2017-08-04 23:05 -0700
      Re: What is ProDOS Error Code 3? Bill Chatfield <billchatfield1@gmail.com> - 2017-08-04 23:28 -0700

Page 1 of 2 [1] 2 Next page →

#3726 — What is ProDOS Error Code 3?

From	Bill Chatfield <billchatfield1@gmail.com>
Date	2017-07-22 01:31 -0700
Subject	What is ProDOS Error Code 3?
Message-ID	<bbef948a-8740-4398-bcf7-21ffa1044563@googlegroups.com>

I've written a program that calls MLI ON_LINE and displays all the online volume names. Running it under AppleWin (in Wine on Linux), it produces an error code 3 for S7D2 which has no disk assigned to it in AppleWin. Does anyone know what the undocumented error code 3 is?

This is the output:

]-ONLINE
S7,D1 /HD1
S7,D2 (UNKNOWN ERROR CODE: 03)
S6,D1 /A2OSX.BOOT
S6,D2 /A2OSX.DEV
S3,D2 /RAM

This is the code:

********************************
*                              *
* ONLINE - LISTS ALL VOLUMES   *
*                              *
* AUTHOR:  BILL CHATFIELD      *
* LICENSE: GPL2                *
*                              *
********************************

               ORG   $2000
               DSK   /HD1/SRC/ONLINE
               TYP   $FF        ;SYSTEM TYPE

********************************
*                              *
* CONSTANTS                    *
*                              *
********************************

DEBUG          EQU   0
ONLCMD         EQU   $C5        ;ID FOR ON_LINE MLI SYSTEM CALL
RDKEY          EQU   $FD0C      ;READS 1 CHAR
CROUT          EQU   $FD8E      ;SUB TO OUTPUT CARRIAGE RETURN
COUT           EQU   $FDED      ;SUB TO OUTPUT A CHARACTER
PRBYTE         EQU   $FDDA      ;SUB TO PRINT ERROR MESSAGE
MLI            EQU   $BF00      ;ADDRESS OF MLI ENTRY POINT
BELL           EQU   $FF3A      ;SUBROUTINE TO BEEP
MAXREC         EQU   16         ;MAX RECS RETURNED BY ON_LINE
BUFPTR         EQU   6          ;WILL USE ZERO PAGE 6 & 7
MSGADR         EQU   8
RECLEN         EQU   $10        ;THAT'S 16 IN DECIMAL

********************************
*                              *
* MACROS                       *
*                              *
********************************

               DO    0          ;TURN OFF ASSEMBLY FOR MACROS

********************************
*                              *
* PUTS                         *
*                              *
********************************

PUTS           MAC
               TYA              ;PRESERVE Y
               PHA
               LDY   #0         ;PREPARE LOOP INDEX
]NEXTCHR       LDA   ]1,Y       ;LOAD A CHARACTER
               CMP   #0         ;CHECK FOR END OF STRING
               BEQ   FINISH
               JSR   COUT
               INY
               JMP   ]NEXTCHR
FINISH         PLA              ;RESTORE Y
               TAY
               EOM

********************************
*                              *
* PAUSE                        *
*                              *
********************************

PAUSE          MAC
               PUTS  DPAUSE
               JSR   RDKEY
               JSR   CROUT
               EOM

ADD2ADDR       MAC
               LDA   ]1
               CLC
               ADC   ]2
               STA   ]1
               BCC   DONE
               INC   ]1+1
DONE           EOM

               FIN              ;END OF MACROS

********************************
*                              *
* MAIN                         *
*                              *
********************************

MAIN
               JSR   MLI        ;CALL MACHINE LANGUAGE INTERFACE
               DB    ONLCMD     ;SPECIFY THE ON_LINE SYSTEM CALL
               DA    ONLARGS    ;SPECIFY ADDRESS OF ARGUMENTS
               BEQ   CONTINUE   ;ON_LINE RETURNS 0 ON SUCCESS
               JMP   ERROR
*
* COPY THE ADDRESS OF THE OUTPUT BUFFER INTO BUFPTR
*
CONTINUE       LDA   #<BUFFER   ;PUT LOW BYTE INTO ACCUMULATOR
               STA   BUFPTR     ;ASSIGN LOW BYTE TO BUFPTR
               LDA   #>BUFFER   ;PUT HIGH BYTE INTO ACCUMULATOR
               STA   BUFPTR+1   ;ASSIGN HIGH BYTE TO BUFPTR
*
* LOOP TO PROCESS 16 RECORDS
*
RECLOOP        LDA   RECNUM
               CMP   #MAXREC
               BNE   :CHKLAST
               JMP   ENDPROG
:CHKLAST       LDY   #0
               LDA   (BUFPTR),Y
               CMP   #0         ;LAST REC IF FIRST BYTE IS 0
               BNE   FINDDRV
               JMP   ENDPROG

* FIND DRIVE NUMBER. IT IS SPECIFIED BY THE HIGH BIT OF
* THE FIRST BYTE IN THE RECORD. A ZERO SPECIFIES DRIVE 1.
* A ONE SPECIFIES DRIVE 2.

FINDDRV        LDY   #0         ;SETUP FOR LDA INDIRECT INDEXED
               LDA   (BUFPTR),Y ;LOAD FIRST BYTE INTO ACCUM
               AND   #%10000000 ;FOCUS ON THE HIGH BIT
               CLC              ;DON'T LET THE CARRY BIT WRAP
               LSR              ;SHIFT BITS TO THE RIGHT
               LSR              ;AGAIN
               LSR              ;AGAIN
               LSR              ;...
               LSR
               LSR
               LSR              ;BIT ZERO NOW SPECIFIES DRIVE
               ADC   #1         ;CONVERT BIT TO DRIVE NUMBER
               STA   DRIVENUM   ;STORE THE RESULT
*
* FIND SLOT NUMBER
*
               LDY   #0         ;SETUP FOR NEXT OP
               LDA   (BUFPTR),Y ;LOAD FIRST BYTE INTO ACCUM
               AND   #%01110000 ;FOCUS ON BITS 4,5, AND 6
               LSR              ;SHIFT BITS TO THE RIGHT
               LSR              ;DO IT AGAIN
               LSR              ;DO IT AGAIN
               LSR              ;DO IT AGAIN
               STA   SLOTNUM    ;BITS 0,1,2 NOW SPECIFY SLOT NUM
*
* FIND VOLUME NAME LENGTH
*
               LDY   #0         ;SETUP FOR NEXT OP
               LDA   (BUFPTR),Y ;LOAD FIRST BYTE OF REC INTO A
               AND   #%00001111 ;FOCUS ON LOWER 4 BITS
               STA   NAMELEN    ;STORE THE RESULT

               DO    DEBUG
               PUTS  DNAMELEN
               LDA   NAMELEN
               JSR   PRBYTE
               JSR   CROUT
               FIN
*
* PRINT SLOT AND DRIVE
*
PRTSLOT
               LDA   #"S"       ;AN 'S' WITH HIGH BIT SET
               JSR   COUT       ;WRITE 'S'
               LDA   SLOTNUM    ;PUT SLOT NUM IN ACCUMULATOR
               CLC              ;CLEAR CARRY FLAG FOR ADDITION
               ADC   #$B0       ;CONVERT TO ASCII & SET HI BIT
               JSR   COUT       ;PRINT SLOTNUM
               LDA   #","       ;COMMA WITH HIGH BIT SET
               JSR   COUT       ;WRITE COMMA
               LDA   #"D"       ;A 'D' WITH HIGH BIT SET
               JSR   COUT       ;WRITE 'D'
               LDA   DRIVENUM   ;PUT DRIVE NUM IN ACCUMULATOR
               CLC              ;CLEAR CARRY FLAG FOR ADDITION
               ADC   #$B0       ;CONVERT TO ASCII & SET HI BIT
               JSR   COUT       ;WRITE DRIVENUM CHARACTER
               LDA   #" "       ;SPACE WITH HIGH BIT SET
               JSR   COUT       ;WRITE SPACE CHARACTER
*
* CHECK FOR EMPTY VOLUME NAME
*
               LDY   #0
               CPY   NAMELEN    ;CHECK FOR EMPTY NAME
               BNE   WRITEVOL   ;CONTINUE IF IT IS NOT EMPTY
               INY              ;MOVE INDEX TO LOC OF ERROR CODE
               LDA   (BUFPTR),Y ;LOAD THE ERROR CODE
               JSR   WRITEERR
               JSR   CROUT
               JMP   INCREC
*
* PRINT THE VOLUME NAME
*
WRITEVOL       LDA   #"/"       ;SLASH WITH HIGH BIT SET
               JSR   COUT       ;WRITE SLASH CHARACTER
               LDY   #1         ;SET INDEX TO FIRST CHAR OF NAME
:NEXTCHR       LDA   (BUFPTR),Y ;LOAD CHAR INTO ACCUMULATOR
               ORA   #%10000000 ;TURN ON THE HIGH BIT FOR PRINT
               JSR   COUT       ;WRITE A CHARACTER OF VOL NAME
               CPY   NAMELEN    ;CHECK IF LAST CHARACTER
               BEQ   :DONEVOL   ;EXIT LOOP IF DONE
               INY              ;INCREMENT Y REGISTER
               JMP   :NEXTCHR   ;LOOP TO NEXT CHARACTER
:DONEVOL       JSR   CROUT      ;WRITE A CARRIAGE RETURN
*
* BOTTOM OF RECLOOP
*
INCREC         INC   RECNUM     ;INCREMENT CURRENT RECORD NUM
*
* ADD 16 TO THE ADDRESS IN BUFPTR
*
               LDA   BUFPTR     ;LOAD THE LOW BYTE OF BUFPTR
               CLC              ;CLEAR CARRY BIT IN PREP FOR ADD
               ADC   #RECLEN    ;ADD RECLEN TO LOW BYTE
               STA   BUFPTR     ;STORE CALCULATED LOW BYTE
               BCC   :NOCARRY   ;IF CARRY NOT SET THEN NEXT REC
               INC   BUFPTR+1   ;INC HIGH BYTE IF CARRY WAS SET
:NOCARRY
               DO    DEBUG
               PAUSE
               FIN

               JMP   RECLOOP    ;LOOP TO NEXT RECORD
ENDPROG
               RTS              ;RETURN TO WHATEVER CALLED PROG
*
* ERROR HANDLER
*
ERROR
               JSR   WRITEERR
               JSR   BELL       ;BEEP
               JSR   CROUT      ;WRITE CARRIAGE RETURN
               RTS              ;RETURN TO WHATEVER CALL PROGRAM

********************************
*                              *
* SUB WRITEERR                 *
* ERROR CODE MUST BE IN ACCUM  *
*                              *
********************************

WRITEERR
               STA   ERRCODE
               LDX   #0
               LDY   #0

:NEXTERR
               DO    DEBUG
               PUTS  DERRCODE
               LDA   ERRCODE
               JSR   PRBYTE
               JSR   CROUT
               FIN

               LDA   ERRCODE
               CMP   ERRCODES,X
               BEQ   :FOUND
               INX
               INY
               INY
               CPX   ERRCOUNT
               BMI   :NEXTERR

* UNKNOWN ERROR CODE
               LDA   #"("
               JSR   COUT
               PUTS  UNKECODE
               LDA   ERRCODE
               JSR   PRBYTE
               LDA   #")"
               JSR   COUT
               JMP   :ENDSUB

:FOUND         LDA   ERRMSGS,Y  ;LOAD A WITH LOW BYTE OF MSG
               STA   MSGADR     ;STORE LOW BYTE INTO LOCAL
               INY              ;ADVANCE TO HIGH BYTE
               LDA   ERRMSGS,Y  ;LOAD A WITH HIGH BYTE OF MSG
               STA   MSGADR+1   ;STORE HIGH BYTE INTO LOCAL

               DO    DEBUG
               PUTS  DMSGADR
               LDA   MSGADR
               JSR   PRBYTE
               JSR   CROUT
               FIN

               LDA   #"("
               JSR   COUT
               PUTS  (MSGADR)   ;WRITE THE ERROR MESSAGE
               LDA   #")"
               JSR   COUT

:ENDSUB        RTS

********************************
*                              *
* VARIABLES                    *
*                              *
********************************

BUFFER         DS    256        ;SPACE FOR 16 DISK VOL RECORDS
ONLARGS        DB    2          ;PARAMETER COUNT
               DB    0          ;UNIT NUMBER, 0=ALL
               DA    BUFFER     ;ADDRESS OF OUTPUT BUFFER
DRIVENUM       DB    0          ;BYTE TO STORE DRIVENUM
SLOTNUM        DB    0          ;BYTE TO STORE SLOTNUM
NAMELEN        DB    0          ;LENGTH OF A VOLUME NAME
RECNUM         DB    0          ;CURRENT RECORD NUMBER
ERRCODE        DB    0
DNAMELEN       ASC   "NAMELEN=",00
DERRCODE       ASC   "ERRCODE=",00
DMSGADR        ASC   "MSGADR=",00
DPAUSE         ASC   "PRESS ANY KEY TO CONTINUE",00
UNKECODE       ASC   "UNKNOWN ERROR CODE: ",00
*
* ERROR MESSAGES
*
ERRCOUNT       DB    8
ERR27          ASC   "I/O ERROR",00
ERR28          ASC   "DEVICE NOT CONNECTED",00
ERR2E          ASC   "DISK SWITCHED: FILE STILL OPEN ON OTHER DISK",00
ERR45          ASC   "VOLUME DIRECTORY NOT FOUND",00
ERR52          ASC   "NOT A PRODOS DISK",00
ERR55          ASC   "VOLUME CONTROL BLOCK FULL",00
ERR56          ASC   "BAD BUFFER ADDRESS",00
ERR57          ASC   "DUPLICATE VOLUME",00
*
* ERROR CODE TO MESSAGE TRANSLATION TABLE
*
ERRCODES       DB    $27
               DB    $28
               DB    $2E
               DB    $45
               DB    $52
               DB    $55
               DB    $56
               DB    $57
ERRMSGS        DA    ERR27
               DA    ERR28
               DA    ERR2E
               DA    ERR45
               DA    ERR52
               DA    ERR55
               DA    ERR56
               DA    ERR57

[toc] | [next] | [standalone]

#3728

From	gids.rs@sasktel.net
Date	2017-07-22 06:17 -0700
Message-ID	<011d5f45-c715-419b-abec-7874fa3ea21b@googlegroups.com>
In reply to	#3726

Prodos code 3 is documented and according to Beagle Bros code chart it is "No Device Connected"

[toc] | [prev] | [next] | [standalone]

#3732

From	Michael Pohoreski <michael.pohoreski@gmail.com>
Date	2017-07-22 15:03 -0700
Message-ID	<bd7851aa-2260-4561-9114-2af07dd64119@googlegroups.com>
In reply to	#3728

Strange it is a duplicate of $28, no?

File: EQUATES
Line: 70

xnodrv equ $28 ;no device connected.

[toc] | [prev] | [next] | [standalone]

#3734

From	gids.rs@sasktel.net
Date	2017-07-22 22:47 -0700
Message-ID	<38ae7093-a07a-4e6c-9491-f4f23f8f3d07@googlegroups.com>
In reply to	#3732

On Saturday, July 22, 2017 at 4:03:46 PM UTC-6, Michael Pohoreski wrote:
> Strange it is a duplicate of $28, no?
> 
> File: EQUATES
> Line: 70
> 
> xnodrv equ $28 ;no device connected.


I think there might be two different errors codes at play here.

Error #3 is a Basic.system error.


ProDOS MLI Errors
- number in parenthesis is matched to Basic.System errors

$00 - No Error
$01 - Bad Call Number
$04 - Bad Parameter Count
$25 - Interrupt Table Full
$27 - I/O Error
$28 (3) - No Device Connected
$2B (4) - Write Protected
$2D - Device connected but Volume not online
$2E - Disk Switched
$40 ($10) - Invalid Pathname
$41 ($0C) - No Buffers Available
$42 ($0C) - Maximum Number of Files Open
$43 ($12) - Invalid Reference Number
$44 (6) - Directory Not Found
$45 (6) - Volume Not Found
$46 (7) - File Not Found
$47 ($13) - Duplicate File Name
$48 (9) - Volume Full
$49 ($11) - Directory Full
$4A - Incompatible File Format
$4B ($0D) - Unsupported Storage Type
$4C (5) - End of File, No More Data
$4D (2) - Position Out of Range (Beyond EOF)
$4E ($0A) - File Access Error, File Locked
$50 ($14) - File Already Open
$51 - Directory Structure Damaged (Oops!)
$53 ($0B) - Invalid Parameter
$55 - Volume Control Block Table Full (Too Many Volumes)
$56 ($0C) - Bad Buffer Address
$57 - Duplicate Volume
$5A - File Structure Damaged


$BE8B - if error is not found, then returns with I/O Error (8)

Basic.system errors
$00 - No error
$02 - Range Error
$03 - no device connected
$04 - write protected
$05 - end of data
$06 - path not found
$08 - I/O error
$09 - Disk Full
$0A - File Locked
$0B - Invalid Parameter
$0C - No Buffers Available
$0D - File Type Mismatch
$0E - Program Too Large
$0F - Not Direct Command
$10 - Syntax Error
$11 - Directory Full
$12 - File not Open
$13 - Duplicate File name
$14 - File Busy
$15 - File(s) Still Open

[toc] | [prev] | [next] | [standalone]

#3731

From	Michael Pohoreski <michael.pohoreski@gmail.com>
Date	2017-07-22 13:42 -0700
Message-ID	<d53ec0c2-34ce-4909-98e8-8b5126b77dfa@googlegroups.com>
In reply to	#3726

To compile with merlin32, change two lines:

Line 11, to:
                DSK   ONLINE     ;/HD1/SRC/ONLINE 
Line 168, to:
               LDA   #$AD       ;COMMA WITH HIGH BIT SET

[toc] | [prev] | [next] | [standalone]

#3915

From	Bill Chatfield <billchatfield1@gmail.com>
Date	2017-09-07 13:34 -0700
Message-ID	<461df610-2c0c-475d-9a4d-2e8a259beead@googlegroups.com>
In reply to	#3731

On Saturday, July 22, 2017 at 4:42:44 PM UTC-4, Michael Pohoreski wrote:
> To compile with merlin32, change two lines:
> 
> Line 11, to:
>                 DSK   ONLINE     ;/HD1/SRC/ONLINE 
> Line 168, to:
>                LDA   #$AD       ;COMMA WITH HIGH BIT SET

Line 168 should be:
                 LDA   #$AC       ;COMMA WITH HIGH BIT SET

$AD is a dash, not a comma, which I suppose would be fine if you want a dash there but I wanted a comma.

Also, you can now find this on github: https://github.com/gungwald/online

[toc] | [prev] | [next] | [standalone]

#3916

From	Bill Chatfield <billchatfield1@gmail.com>
Date	2017-09-07 13:49 -0700
Message-ID	<381faa0e-94d0-4ed8-84db-fe59af10b20f@googlegroups.com>
In reply to	#3915

On Thursday, September 7, 2017 at 4:34:42 PM UTC-4, Bill Chatfield wrote:
> On Saturday, July 22, 2017 at 4:42:44 PM UTC-4, Michael Pohoreski wrote:
> > To compile with merlin32, change two lines:
> > 
> > Line 11, to:
> >                 DSK   ONLINE     ;/HD1/SRC/ONLINE 
> > Line 168, to:
> >                LDA   #$AD       ;COMMA WITH HIGH BIT SET
> 
> Line 168 should be:
>                  LDA   #$AC       ;COMMA WITH HIGH BIT SET
> 
> $AD is a dash, not a comma, which I suppose would be fine if you want a dash there but I wanted a comma.
> 
> Also, you can now find this on github: https://github.com/gungwald/online

Anyone have an idea how this could be done in DOS 3.3 or know of a program that does it in DOS 3.3?

[toc] | [prev] | [next] | [standalone]

#3733

From	Michael Pohoreski <michael.pohoreski@gmail.com>
Date	2017-07-22 16:23 -0700
Message-ID	<3d7443db-3e5e-436d-a61f-1bca92891505@googlegroups.com>
In reply to	#3726

Since you are using AppleWin, you may be interested in the (ProDOS 2.4.1) debugger symbols for "online"

SYMPRODOS clear
SYMPRODOS on

SYMPRODOS P8.vcb      = D900

SYMPRODOS P8.online   = E1FB
SYMPRODOS P8.olin1    = E217
SYMPRODOS P8.olin2    = E21A
SYMPRODOS P8.olin3    = E222
SYMPRODOS P8.olin4    = E232
SYMPRODOS P8.onlinerr = E24C
SYMPRODOS P8.online1  = E24D
SYMPRODOS P8.rtrnerr  = E26A
SYMPRODOS P8.olin11   = E277
SYMPRODOS P8.olin12   = E283
SYMPRODOS P8.olinerr1 = E28D
SYMPRODOS P8.olinerr2 = E2A9
SYMPRODOS P8.olin13   = E2AB
SYMPRODOS P8.olin14   = E2B4
SYMPRODOS P8.svdevn   = E2C0

SYMPRODOS P8.mvdevnum = E809
SYMPRODOS P8.fnddvcb  = E81B
SYMPRODOS P8.logvcb1  = E891
SYMPRODOS P8.rdblk    = EB9D
SYMPRODOS P8.cmpvcb   = E8DC

SYMPRODOS P8.mvdbufr  = F1A6
SYMPRODOS P8.valdbuf  = FC3B

dw        P8.vcbptr     FE85
db        P8.duplflag   FEA8
db        P8.namcnt     FEAA
db        P8.namptr     FEAC
db        P8.loklst     FEBC
db        P8.cbytes     FECC:FECD

[toc] | [prev] | [next] | [standalone]

#3735

From	rhoem1@gmail.com
Date	2017-07-23 16:23 -0700
Message-ID	<ac57d065-3e01-47a4-bc03-342e47a43765@googlegroups.com>
In reply to	#3733

The Hard drive emulation in Applewin returns a 0x03 when an image is not mounted for a given drive number.  I lifted this from Beneath Apple Prodos, with the assumption that it's an expected device error code.

see: https://github.com/AppleWin/AppleWin/blob/master/source/Harddisk.cpp#L451

[toc] | [prev] | [next] | [standalone]

#3736

From	Michael J. Mahon <mjmahon@aol.com>
Date	2017-07-23 21:47 -0500
Message-ID	<1I6dnbQo-6RIwujEnZ2dnUU7-UvNnZ2d@giganews.com>
In reply to	#3735

<rhoem1@gmail.com> wrote:
> The Hard drive emulation in Applewin returns a 0x03 when an image is not
> mounted for a given drive number.  I lifted this from Beneath Apple
> Prodos, with the assumption that it's an expected device error code.
> 
> see: https://github.com/AppleWin/AppleWin/blob/master/source/Harddisk.cpp#L451
> 

Wouldn't it be BASIC.SYSTEM's job to analyze the $28 ProDOS code and
translate it to 03 for the BASIC environment?

-- 
-michael - NadaNet 3.1 and AppleCrate II:  http://michaeljmahon.com

[toc] | [prev] | [next] | [standalone]

#3754

From	Nick Westgate <nick.westgate@gmail.com>
Date	2017-08-02 16:33 -0700
Message-ID	<17690fb7-26da-478c-9d31-ad2427a6ab01@googlegroups.com>
In reply to	#3736

On Monday, 24 July 2017 14:47:54 UTC+12, mjm...@aol.com  wrote:
> Wouldn't it be BASIC.SYSTEM's job to analyze the $28 ProDOS code and
> translate it to 03 for the BASIC environment?

Yes! Thanks everyone. A nice little improvement.

#define DEVICE_UNKNOWN_ERROR	0x03
->
#define DEVICE_UNKNOWN_ERROR	0x28

Fixes this:
]CAT,S7,D2
I/O ERROR
->
]CAT,S7,D2
NO DEVICE CONNECTED

Cheers,
Nick.

[toc] | [prev] | [next] | [standalone]

#3756

From	Bill Chatfield <billchatfield1@gmail.com>
Date	2017-08-04 23:27 -0700
Message-ID	<e57a7786-b81f-41c3-bb3e-a0ae0d4d679f@googlegroups.com>
In reply to	#3754

On Wednesday, August 2, 2017 at 7:33:26 PM UTC-4, Nick Westgate wrote:
> On Monday, 24 July 2017 14:47:54 UTC+12, mjm...@aol.com  wrote:
> > Wouldn't it be BASIC.SYSTEM's job to analyze the $28 ProDOS code and
> > translate it to 03 for the BASIC environment?
> 
> Yes! Thanks everyone. A nice little improvement.
> 
> #define DEVICE_UNKNOWN_ERROR	0x03
> ->
> #define DEVICE_UNKNOWN_ERROR	0x28
> 
> Fixes this:
> ]CAT,S7,D2
> I/O ERROR
> ->
> ]CAT,S7,D2
> NO DEVICE CONNECTED
> 
> Cheers,
> Nick.

Awesome! Thanks everyone! I can't wait to see that work in AppleWin.

[toc] | [prev] | [next] | [standalone]

#3758

From	Nick Westgate <nick.westgate@gmail.com>
Date	2017-08-04 23:49 -0700
Message-ID	<5962f15c-9580-4ed0-93ad-6e2914bb352a@googlegroups.com>
In reply to	#3756

On Saturday, 5 August 2017 18:27:37 UTC+12, Bill Chatfield  wrote:
> Awesome! Thanks everyone! I can't wait to see that work in AppleWin.

I've already added it. It's in the latest release, 1.26.3.0 (Experimental) - 4 Aug 2017.

Cheers,
Nick.

[toc] | [prev] | [next] | [standalone]

#3759

From	Bill Chatfield <billchatfield1@gmail.com>
Date	2017-08-05 11:58 -0700
Message-ID	<58d5c77e-3d9b-452a-bed4-f7d7b4824f58@googlegroups.com>
In reply to	#3758

On Saturday, August 5, 2017 at 2:49:56 AM UTC-4, Nick Westgate wrote:
> On Saturday, 5 August 2017 18:27:37 UTC+12, Bill Chatfield  wrote:
> > Awesome! Thanks everyone! I can't wait to see that work in AppleWin.
> 
> I've already added it. It's in the latest release, 1.26.3.0 (Experimental) - 4 Aug 2017.
> 
> Cheers,
> Nick.

Here is the final result: https://flic.kr/p/XeymFi

That is a picture of me running my ONLINE program inside AppleWin 1.26.3.0, which is running inside Wine 2.12, which is running inside Fedora Linux 26.

[toc] | [prev] | [next] | [standalone]

#3760

From	James Davis <JPD.Enterprises@outlook.com>
Date	2017-08-06 12:56 -0700
Message-ID	<f8429608-f2d0-4270-95b4-db237481261f@googlegroups.com>
In reply to	#3759

On Saturday, August 5, 2017 at 11:58:50 AM UTC-7, Bill Chatfield wrote:
 
> Here is the final result: https://flic.kr/p/XeymFi
> 
> That is a picture of me running my ONLINE program inside AppleWin 1.26.3.0, which is running inside Wine 2.12, which is running inside Fedora Linux 26.

This is where your link takes me and it is mostly just a black screen with a blue line that keeps regenerating from left to right under the flicker header: 
 
     https://www.flickr.com/photos/9858758@N04/36253049831/

Nothing to look at!

[toc] | [prev] | [next] | [standalone]

#3761

From	D Finnigan <dog_cow@macgui.com>
Date	2017-08-06 20:28 +0000
Message-ID	<dog_cow-1502051573@macgui.com>
In reply to	#3760

James Davis wrote:
> On Saturday, August 5, 2017 at 11:58:50 AM UTC-7, Bill Chatfield wrote:
>  
>> Here is the final result: https://flic.kr/p/XeymFi
>> 
>> That is a picture of me running my ONLINE program inside AppleWin
>> 1.26.3.0, which is running inside Wine 2.12, which is running inside
>> Fedora Linux 26.
> 
> This is where your link takes me and it is mostly just a black screen with
> a blue line that keeps regenerating from left to right under the flicker
> header: 
>  
>      https://www.flickr.com/photos/9858758@N04/36253049831/
> 
> Nothing to look at!
>

Try this: https://c1.staticflickr.com/5/4381/36253049831_ab7288d42b_o.png

Or if that's still no good, try looking at this:
http://macgui.com/upload/gallery/f_0/user_2/regular/upload_3290.jpg


-- 
]DF$
Apple II 40th Anniversary User's Guide:
http://macgui.com/newa2guide/

[toc] | [prev] | [next] | [standalone]

#3762

From	James Davis <JPD.Enterprises@outlook.com>
Date	2017-08-06 14:11 -0700
Message-ID	<f0759e7a-6b0c-4266-93c8-cb2f64683b09@googlegroups.com>
In reply to	#3761

On Sunday, August 6, 2017 at 1:32:57 PM UTC-7, D Finnigan wrote:
> Try this: https://c1.staticflickr.com/5/4381/36253049831_ab7288d42b_o.png
> 
> Or if that's still no good, try looking at this:
> http://macgui.com/upload/gallery/f_0/user_2/regular/upload_3290.jpg

Thanks David,

Those both have viewable pictures.  The first is of source code and AppleWin.  The second is of a colander of tomatoes and a toad or frog.

James Davis

[toc] | [prev] | [next] | [standalone]

#3763

From	Bill Chatfield <billchatfield1@gmail.com>
Date	2017-08-06 20:31 -0700
Message-ID	<4cfe271d-137b-421a-9c41-923b0bbd4942@googlegroups.com>
In reply to	#3762

On Sunday, August 6, 2017 at 5:11:02 PM UTC-4, James Davis wrote:
> On Sunday, August 6, 2017 at 1:32:57 PM UTC-7, D Finnigan wrote:
> > Try this: https://c1.staticflickr.com/5/4381/36253049831_ab7288d42b_o.png
> > 
> > Or if that's still no good, try looking at this:
> > http://macgui.com/upload/gallery/f_0/user_2/regular/upload_3290.jpg
> 
> Thanks David,
> 
> Those both have viewable pictures.  The first is of source code and AppleWin.  The second is of a colander of tomatoes and a toad or frog.
> 
> James Davis

The colander of tomatoes and the toad picture is not mine. :-) The first one with source code and AppleWin is mine. It's showing the ONLINE program output with the "DEVICE NOT CONNECTED" error, which is what the update to AppleWin was supposed to provide.

I don't know why the original link does not work for you. It works for me in Firefox on Fedora which I would think is the one that would be broken if anything was broken. What are you using to view it?

[toc] | [prev] | [next] | [standalone]

#3764

From	James Davis <JPD.Enterprises@outlook.com>
Date	2017-08-06 23:35 -0700
Message-ID	<efd8742b-02dc-4314-af26-570e35e5c6c6@googlegroups.com>
In reply to	#3763

On Sunday, August 6, 2017 at 8:31:33 PM UTC-7, Bill Chatfield wrote:

> I don't know why the original link does not work for you. It works for me in Firefox on Fedora which I would think is the one that would be broken if anything was broken. What are you using to view it?

I use (Windows 7/64) Microsoft Internet Explorer 11/64 with maximum security: Protected Mode is ON; Scripts do not execute; No Java; No Flash; etc.  There are lots of websites and/or webpages that I cannot always see.  If they do not conform to HTML 4 or 5 only, then I don't see the extra stuff they may have.  I don't care if I cannot view them; I would rather be safe than sorry.

[toc] | [prev] | [next] | [standalone]

#3765

From	Bill Chatfield <billchatfield1@gmail.com>
Date	2017-08-07 10:14 -0700
Message-ID	<9a3cf03f-2060-49fa-92c1-8a3342484b7e@googlegroups.com>
In reply to	#3764

On Monday, August 7, 2017 at 2:35:25 AM UTC-4, James Davis wrote:
> On Sunday, August 6, 2017 at 8:31:33 PM UTC-7, Bill Chatfield wrote:
> 
> > I don't know why the original link does not work for you. It works for me in Firefox on Fedora which I would think is the one that would be broken if anything was broken. What are you using to view it?
> 
> I use (Windows 7/64) Microsoft Internet Explorer 11/64 with maximum security: Protected Mode is ON; Scripts do not execute; No Java; No Flash; etc.  There are lots of websites and/or webpages that I cannot always see.  If they do not conform to HTML 4 or 5 only, then I don't see the extra stuff they may have.  I don't care if I cannot view them; I would rather be safe than sorry.

How do you live without Facebook? ;-)

[toc] | [prev] | [next] | [standalone]

Page 1 of 2 [1] 2 Next page →

csiph-web

What is ProDOS Error Code 3?

Contents

#3726 — What is ProDOS Error Code 3?

#3728

#3732

#3734

#3731

#3915

#3916

#3733

#3735

#3736

#3754

#3756

#3758

#3759

#3760

#3761

#3762

#3763

#3764

#3765