Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #10972 > unrolled thread

Re: Differential Equation: Not getting result

Started byBob Hanlon <hanlonr357@gmail.com>
First post2012-07-18 05:40 +0000
Last post2012-07-18 05:40 +0000
Articles 1 — 1 participant

Back to article view | Back to comp.soft-sys.math.mathematica

This discussion starts older than the indexed window; earlier articles aren't shown. The article labeled Started by below is the oldest one visible, not the original post.


Contents

  Re: Differential Equation: Not getting result Bob Hanlon <hanlonr357@gmail.com> - 2012-07-18 05:40 +0000

#10972 — Re: Differential Equation: Not getting result

FromBob Hanlon <hanlonr357@gmail.com>
Date2012-07-18 05:40 +0000
SubjectRe: Differential Equation: Not getting result
Message-ID<ju5i8a$3ru$1@smc.vnet.net>
Clear[x];
r = 1;
K = 1;
eqn = x'[t] - r x[t] (1 - x[t]/K) == 0;
sol = NDSolve[
    {eqn, x[0] == 1/2}, x[t],
    {t, 0, 50}][[1]];

ParametricPlot[
 Evaluate[{x[t] /. sol, D[x[t] /. sol, t]}],
 {t, 0, 50},
 Frame -> True,
 AxesLabel -> {"x", Overscript[x, "."]},
 AspectRatio -> 1]

ParametricPlot[
 Evaluate[{t, x[t] /. sol}],
 {t, 0, 50},
 Frame -> True,
 AxesLabel -> {"t", "x"},
 AspectRatio -> 1]

Or with DSolve

sol2 = DSolve[
    {eqn, x[0] == 1/2}, x[t], t][[1]] // Quiet

{x[t] -> E^t/(1 + E^t)}

D[sol2, t] // Simplify

{Derivative[1][x][t] -> E^t/(1 + E^t)^2}


Bob Hanlon


On Tue, Jul 17, 2012 at 1:31 AM, Rahul Chakraborty
<rahul.6sept@gmail.com> wrote:
> Dear all,
>
>  For the following code i'm not getting result. kindly tell me where i'm making mistake.
>
> Clear[x];
> r=1;
> K=1;
> eqn= (x^')[t]-r  x[t]  (1-x[t]/K)==0//Simplify;
> sol=NDSolve[{eqn,x[0]==1/2,x'[0]==0},x[t],{t,0,50}][[1]]
> ParametricPlot[Evaluate[{x[t]/.sol,D[x[t]/.sol,t]}],{t,0,50},Frame->True,AxesLabel->{"x",Overscript[x,"."]},AspectRatio->1]
> ParametricPlot[Evaluate[{t,x[t]/.sol}],{t,0,50},Frame->True,AxesLabel->{"t","x"},AspectRatio->1]
>
>
> Regards,
> rc
>

[toc] | [standalone]


Back to top | Article view | comp.soft-sys.math.mathematica


csiph-web