Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #10854 > unrolled thread

Re: 3d artifacts

Started byBob Hanlon <hanlonr357@gmail.com>
First post2012-07-09 09:24 +0000
Last post2012-07-20 07:51 +0000
Articles 2 — 2 participants

Back to article view | Back to comp.soft-sys.math.mathematica

This discussion starts older than the indexed window; earlier articles aren't shown. The article labeled Started by below is the oldest one visible, not the original post.


Contents

  Re: 3d artifacts Bob Hanlon <hanlonr357@gmail.com> - 2012-07-09 09:24 +0000
    Re: 3d artifacts Roger Bagula <roger.bagula@gmail.com> - 2012-07-20 07:51 +0000

#10854 — Re: 3d artifacts

FromBob Hanlon <hanlonr357@gmail.com>
Date2012-07-09 09:24 +0000
SubjectRe: 3d artifacts
Message-ID<jte808$ss6$1@smc.vnet.net>
Resent since this hasn't shown up.

On Sat, Jul 7, 2012 at 8:14 AM, Bob Hanlon <hanlonr357@gmail.com> wrote:
> Use Exclusions or define the functions with Piecewise
>
> g[t_] = -Pi/2 + Mod[t, Pi];
>
> f[t_] = If[-Pi/2 <= t <= Pi/2,
>    (1 - Cos[2 t])/2, (-1 + Cos[2 t])/2];
>
> ParametricPlot3D[{f[t] g[t], g[t]^2, f[t]},
>  {t, -Pi, Pi}, Exclusions -> {-Pi/2, Pi/2}]
>
> f[t_] = Piecewise[
>    {{(1 - Cos[2 t])/2, -Pi/2 <= t <= Pi/2}},
>    (-1 + Cos[2 t])/2];
>
> ParametricPlot3D[{f[t] g[t], g[t]^2, f[t]},
>  {t, -Pi, Pi}]
>
> ww[t_] := If[0 <= t < 2 Pi,
>    {Cos[t], Sin[t], Sin[2 t]},
>    If[2 Pi <= t <= 4 Pi,
>     {Sin[2 t], 15/10 Cos[t]/(1 + Sin[t]^2), Sin[t]/(1 + Sin[t]^2)},
>     {Cos[t], Sin[t], Sin[2 t]}]];
>
> ParametricPlot3D[ww[t], {t, 0, 4 Pi},
>  Exclusions -> {2 Pi, 4 Pi}]
>
> ww[t_] := Piecewise[
>    {{{Cos[t], Sin[t], Sin[2 t]},
>      0 <= t < 2 Pi},
>     {{Sin[2 t], 15/10 Cos[t]/(1 + Sin[t]^2), Sin[t]/(1 + Sin[t]^2)},
>      2 Pi <= t <= 4 Pi}},
>    {Cos[t], Sin[t], Sin[2 t]}];
>
> ParametricPlot3D[ww[t], {t, 0, 4 Pi}]
>
>
> Bob Hanlon
>
>
> On Sat, Jul 7, 2012 at 5:30 AM, Roger Bagula <roger.bagula@gmail.com> wrote:
>> In the two part defintion:
>>
>> f[t_] = If [ t >= -Pi/2 && t <= Pi/2, (1 - Cos[2*t])/2, (-1 + Cos[2*t])/2];
>> g[t_] = -Pi/2 + Mod[t, Pi];
>> ParametricPlot3D[{f[t]*g[t], g[t]*g[t], f[t]}, {t, -Pi, Pi}]
>>
>> A "handle" appears between the two parts of the curve.
>> I got the same effect when I tried to get a
>> patched manifold for the Whitehead Link:
>>
>> x = Cos[t];
>> z = Sin[t];
>> y = 2*Cos[t]*Sin[t];
>> w = {x, y, z};
>> {z1, y1} = 1/(1 + Sin[t]^2) {15/10 Cos[t], Sin[t] };
>> x1 = 2*Cos[t]*Sin[t];
>> w1 = {x1, y1, z1};
>> (* patched manifold function for Whitehead link*)
>> ww[t_] :=
>>   If[t >= 0 && t < 2*Pi, {Cos[t], Sin[t], Sin[2*t]},
>>    If[t >= 2*Pi && t <= 4*Pi, {Sin[2*t], 15/10 Cos[t]/(1 + Sin[t]^2),
>>      Sin[t]/(1 + Sin[t]^2)}, {Cos[t], Sin[t], Sin[2*t]}]];
>> ParametricPlot3D[ww[t], {t, 0, 4*Pi + 0.01}]
>>
>> I'd like to remove that artifact handle
>> by some simple method.
>>



-- 
Bob Hanlon

[toc] | [next] | [standalone]


#10988

FromRoger Bagula <roger.bagula@gmail.com>
Date2012-07-20 07:51 +0000
Message-ID<jub2le$efv$1@smc.vnet.net>
In reply to#10854
Bob Hanlon
You and Park both thought exceptions would work.
Once add an tube function Parametric3D
no longer performs the Exceptions it appears.
I tried a tube program  that usually works 
and then my triaxial tubes topological product method:
Clear[ww, x, t, p, f, g]
(* patched manifold function for Whitehead link*)
ww[t_, p_] := 
  If[t >= 0 && 
    t < 2*Pi, {(10 + Cos[p])*Cos[t], (10 + Cos[p + 2*Pi/3])*
     Sin[t], (10 + Cos[p - 2*Pi/3])*Sin[2*t]}, 
   If[t >= 2*Pi && 
     t <= 4*Pi, {(10 + Cos[p])*
      Sin[2*t], (10 + Cos[p + 2*Pi/3])*15/
       10 Cos[t]/(1 + Sin[t]^2), (10 + Cos[p - 2*Pi/3])*
      Sin[t]/(1 + Sin[t]^2)}, {(10 + Cos[p])*
      Cos[t], (10 + Cos[p + 2*Pi/3])*Sin[t], (10 + Cos[p - 2*Pi/3])*
      Sin[2*t]}]];
ParametricPlot3D[ww[t, p], {t, 0, 4*Pi + 0.01}, {p, 0, 2*Pi}, 
 Exclusions -> {2 Pi, 4 Pi}, Boxed -> False, Axes -> False, 
 ColorFunction -> "GreenBrownTerrain", MeshFunctions -> {#3 &}, 
 PlotPoints -> {35, 100}]
ParametricPlot3D[ww[t, p], {t, 0, 4*Pi + 0.01}, {p, 0, 2*Pi}, 
 Exclusions -> Range[0, 4 \[Pi], \[Pi]/4], Boxed -> False, 
 Axes -> False, ColorFunction -> "GreenBrownTerrain", 
 MeshFunctions -> {#3 &}, PlotPoints -> {35, 100}]
(* bicuspoid manifold definition*)
f[t_] = If [ 
   t >= -Pi/2 && t <= Pi/2, (1 - Cos[2*t])/2, (-1 + Cos[2*t])/2];
g[t_] = -Pi/2 + Mod[t, Pi];
ParametricPlot3D[{(10 + Cos[p])*f[t]*g[t], (10 + Cos[p + 2*Pi/3])*
   g[t]*g[t], (10 + Cos[p - 2*Pi/3])*f[t]}, {t, -Pi, Pi}, {p, 0, 
  2*Pi}, Exclusions -> Range[-\[Pi], \[Pi], \[Pi]/4], Boxed -> False, 
 Axes -> False, ColorFunction -> "GreenBrownTerrain", 
 MeshFunctions -> {#3 &}, PlotPoints -> {35, 100}]
ParametricPlot3D[{(10 + Cos[p])*f[t]*g[t], (10 + Cos[p + 2*Pi/3])*
   g[t]*g[t], (10 + Cos[p - 2*Pi/3])*f[t]}, {t, -Pi, Pi}, {p, 0, 
  2*Pi}, Exclusions -> {-Pi/2, Pi/2}, Boxed -> False, Axes -> False, 
 ColorFunction -> "GreenBrownTerrain", MeshFunctions -> {#3 &}, 
 PlotPoints -> {35, 100}]

On Monday, July 9, 2012 2:24:24 AM UTC-7, Bob Hanlon wrote:
> Resent since this hasn&#39;t shown up.


[toc] | [prev] | [standalone]


Back to top | Article view | comp.soft-sys.math.mathematica


csiph-web