Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #10129 > unrolled thread

clearing a variable with a dummy subscript

Started byAndre Hautot <ahautot@ulg.ac.be>
First post2012-05-18 09:27 +0000
Last post2012-05-21 09:59 +0000
Articles 4 — 4 participants

Back to article view | Back to comp.soft-sys.math.mathematica


Contents

  clearing a variable with a dummy subscript Andre Hautot <ahautot@ulg.ac.be> - 2012-05-18 09:27 +0000
    Re: clearing a variable with a dummy subscript A Retey <awnl@gmx-topmail.de> - 2012-05-19 09:44 +0000
    Re: clearing a variable with a dummy subscript Peter Breitfeld <phbrf@t-online.de> - 2012-05-20 06:34 +0000
    Re: clearing a variable with a dummy subscript Christoph Lhotka <christoph.lhotka@fundp.ac.be> - 2012-05-21 09:59 +0000

#10129 — clearing a variable with a dummy subscript

FromAndre Hautot <ahautot@ulg.ac.be>
Date2012-05-18 09:27 +0000
Subjectclearing a variable with a dummy subscript
Message-ID<jp54mp$gos$1@smc.vnet.net>
Hi !
Here is something very simple I don't understand :

f[x_] := x; f[2]    (*A function*)
 2

Clear[f]; f[2]       (*The same perfectly cleared as expected*)
f[2]


Subscript[u, k_] := k; Subscript[u, 2]        (*u with subscript k_ 
entered via the palette*)
 2

Clear[u]; Subscript[u, 2]          (*I found no way to clear u; a 
suggestion ?)
2

Thanks in advance,

ahautot

[toc] | [next] | [standalone]


#10147

FromA Retey <awnl@gmx-topmail.de>
Date2012-05-19 09:44 +0000
Message-ID<jp7q12$qda$1@smc.vnet.net>
In reply to#10129
Am 18.05.2012 11:27, schrieb Andre Hautot:
> Hi !
> Here is something very simple I don't understand :
>
> f[x_] := x; f[2]    (*A function*)
>   2
>
> Clear[f]; f[2]       (*The same perfectly cleared as expected*)
> f[2]
>
>
> Subscript[u, k_] := k; Subscript[u, 2]        (*u with subscript k_
> entered via the palette*)
>   2
>
> Clear[u]; Subscript[u, 2]          (*I found no way to clear u; a
> suggestion ?)
> 2
>

Use:

Subscript[u, k_] =.

or (if you don't have other definitions for Subscript you want to keep):

Clear[Subscript]

the deeper reason is that this rule is stored in the DownValues of 
Subscript:

Subscript[u, k_] := k;
DownValues[Subscript]

What you probably want to do is to store it as an UpValue to u instead 
of a DownValue of Subscript:

u /: Subscript[u, k_] := k

DownValues[Subscript]
UpValues[u]

now you can get rid of the definition as expected:

Clear[u]

Subscript[u,2]


hth,

albert

[toc] | [prev] | [next] | [standalone]


#10160

FromPeter Breitfeld <phbrf@t-online.de>
Date2012-05-20 06:34 +0000
Message-ID<jpa3ag$44k$1@smc.vnet.net>
In reply to#10129
Andre Hautot wrote:

> Hi !
> Here is something very simple I don't understand :
>
> f[x_] := x; f[2]    (*A function*)
>  2
>
> Clear[f]; f[2]       (*The same perfectly cleared as expected*)
> f[2]
>
>
> Subscript[u, k_] := k; Subscript[u, 2]        (*u with subscript k_ 
> entered via the palette*)
>  2
>
> Clear[u]; Subscript[u, 2]          (*I found no way to clear u; a 
> suggestion ?)
> 2
>
> Thanks in advance,
>
> ahautot
>
>

The values of supcripted Variables are not associated with u, but to
Subscript:

Subscript[u,2]=123

DownValues[u]   returns: {}

DownValues[Subscript]   returns: {HoldPattern[u_2]:>123}

So to Clear, you must call:

Clear[Subscript]

(but then *all* subscripted variables are cleared)

-- 
_________________________________________________________________
Peter Breitfeld | Bad Saulgau, Germany | http://www.pBreitfeld.de

[toc] | [prev] | [next] | [standalone]


#10166

FromChristoph Lhotka <christoph.lhotka@fundp.ac.be>
Date2012-05-21 09:59 +0000
Message-ID<jpd3lb$ecb$1@smc.vnet.net>
In reply to#10129
Hello,

a workaround could be to delete just the entries of DownValues
which contain the symbol u.

To demonstrate I add to your example

Subscript[u, k_] := k; Subscript[u, 2]
2

another one of similar form:

Subscript[v, k_] := k; Subscript[v, 2]
2

Here are the values stored in the down values list of subscript:

DownValues[Subscript]

{HoldPattern[Subscript[v, k_]] :> k,  HoldPattern[Subscript[u, k_]] :> k}

To delete definitions made just to u use something like

DownValues[Subscript] = Select[DownValues[Subscript], FreeQ[#, u, 
\[Infinity]] &]
{HoldPattern[Subscript[v, k_]] :> k}

Now the definition for u_k is deleted

Subscript[u, 2]
Subscript[u, 2]

while the definition for v_k is still present

Subscript[v, 2]
2

To this end you could define something like:

myClear[x_Symbol] := Block[{},
DownValues[Subscript] = Select[DownValues[Subscript], FreeQ[#, x, 
\[Infinity]] &]];

which works as expected:

myClear[v];Subscript[v,2]
Subscript[v,2]

Hope that helps,

Christoph



On 05/20/2012 08:34 AM, Peter Breitfeld wrote:
> Andre Hautot wrote:
>
>> Hi !
>> Here is something very simple I don't understand :
>>
>> f[x_] := x; f[2]    (*A function*)
>>   2
>>
>> Clear[f]; f[2]       (*The same perfectly cleared as expected*)
>> f[2]
>>
>>
>> Subscript[u, k_] := k; Subscript[u, 2]        (*u with subscript k_
>> entered via the palette*)
>>   2
>>
>> Clear[u]; Subscript[u, 2]          (*I found no way to clear u; a
>> suggestion ?)
>> 2
>>
>> Thanks in advance,
>>
>> ahautot
>>
>>
> The values of supcripted Variables are not associated with u, but to
> Subscript:
>
> Subscript[u,2]=123
>
> DownValues[u]   returns: {}
>
> DownValues[Subscript]   returns: {HoldPattern[u_2]:>123}
>
> So to Clear, you must call:
>
> Clear[Subscript]
>
> (but then *all* subscripted variables are cleared)
>

[toc] | [prev] | [standalone]


Back to top | Article view | comp.soft-sys.math.mathematica


csiph-web