Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #8815 > unrolled thread

Re: Plotting colorfunctions over multiple parametric curves

Started by"djmpark" <djmpark@comcast.net>
First post2012-03-01 10:39 +0000
Last post2012-03-01 10:39 +0000
Articles 1 — 1 participant

Back to article view | Back to comp.soft-sys.math.mathematica

This discussion starts older than the indexed window; earlier articles aren't shown. The article labeled Started by below is the oldest one visible, not the original post.


Contents

  Re: Plotting colorfunctions over multiple parametric curves "djmpark" <djmpark@comcast.net> - 2012-03-01 10:39 +0000

#8815 — Re: Plotting colorfunctions over multiple parametric curves

From"djmpark" <djmpark@comcast.net>
Date2012-03-01 10:39 +0000
SubjectRe: Plotting colorfunctions over multiple parametric curves
Message-ID<jinjkl$d2s$1@smc.vnet.net>
Andrew,

The proper procedure is to set ColorFunctionScaling to False, and then use
the Rescale function to map the potential range onto the interval 0 to 1.

n = 3;
XYR = ({{-2.1, 0, 1.0}, {0, 0, 0.5}, {2.1, 0, 1.0}});
x[i_] := XYR[[i, 1]];
y[i_] := XYR[[i, 2]];
r[i_] := XYR[[i, 3]];

potential[theta_, i_] := theta + 1.0;
circle[i_, theta_] := {x[i] + r[i]*Cos[theta], y[i] + r[i]*Sin[theta]};

Show[
 Table[
  ParametricPlot[circle[i, theta], {theta, 0, 2 Pi},
   PlotStyle -> Thick,
   Axes -> False,
   ImageSize -> 200,
   ColorFunction ->
    Function[{x, y, theta}, 
     ColorData["TemperatureMap"][
      Rescale[potential[theta, i], {1, 2 \[Pi] + 1}]]],
   ColorFunctionScaling -> False], {i, 1, n}],
 PlotRange -> All] 

The plotting could be done a little more simply using the Presentations
application.

<<Presentations`

Draw2D[
 {Thick,
  ParametricDraw[circle[#, theta], {theta, 0, 2 \[Pi]},
     ColorFunction ->
      Function[{x, y, theta}, 
       ColorData["TemperatureMap"][
        Rescale[potential[theta, #], {1, 2 \[Pi] + 1}]]],
     ColorFunctionScaling -> False
     ] & /@ {1, 2, 3}},
 ImageSize -> 200]


David Park
djmpark@comcast.net 
http://home.comcast.net/~djmpark/index.html 





From: Andrew Green [mailto:kiwibooga@googlemail.com] 


Hi Bob

Thanks for the reply. I am a step further thank you, but the results are
strange.  It is as if the colorfunction is clipping values below 0 and above
1 - it is not scaling even if ColorFunctionScaling->true is added. Consider
potential[theta_,i_] = theta+1.0, I would have expected you should still get
a full rainbow of colors (0 to 2pi mapped to 0 to 1), instead all are red.

n = 3;
XYR = ( {
    {-2.1, 0, 1.0},
    {0, 0, 0.5},
    {2.1, 0, 1.0}
   } );
x[i_] := XYR[[i, 1]];
y[i_] := XYR[[i, 2]];
r[i_] := XYR[[i, 3]];

potential[theta_, i_] := theta + 1.0;
circle[i_, theta_] := {x[i] + r[i]*Cos[theta], y[i] + r[i]*Sin[theta]};

Show[Table[
  ParametricPlot[circle[i, theta], {theta, 0, 2 Pi}, 
   PlotStyle -> Thick, Axes -> False, ImageSize -> 200, 
   ColorFunction -> 
    Function[{x, y, theta}, 
     ColorData["TemperatureMap"][potential[theta, i]]], 
   ColorFunctionScaling -> True], {i, 1, n}], PlotRange -> All]

Any ideas why?

Thanks - Andrew

[toc] | [standalone]


Back to top | Article view | comp.soft-sys.math.mathematica


csiph-web