Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #7836 > unrolled thread

Re: Vectors

Started byBob Hanlon <hanlonr357@gmail.com>
First post2012-01-14 22:18 +0000
Last post2012-01-14 22:18 +0000
Articles 1 — 1 participant

Back to article view | Back to comp.soft-sys.math.mathematica

This discussion starts older than the indexed window; earlier articles aren't shown. The article labeled Started by below is the oldest one visible, not the original post.


Contents

  Re: Vectors Bob Hanlon <hanlonr357@gmail.com> - 2012-01-14 22:18 +0000

#7836 — Re: Vectors

FromBob Hanlon <hanlonr357@gmail.com>
Date2012-01-14 22:18 +0000
SubjectRe: Vectors
Message-ID<jesv04$cna$1@smc.vnet.net>
r = {Reduce[{x - 1 == (y + 1)/2 == (z - 3)/h, h != 0}, {h, y},
    Backsubstitution -> True] // ToRules}

{{z -> 3, x -> 1, y -> -1}, {h -> (-3 + z)/(-1 + x), y -> -3 + 2*x}}

h /. r[[2]]

(-3 + z)/(-1 + x)

eqns = {6 x - 2 y + z == 11, x - 1 == (y + 1)/2};

parametricLine[x_] = {x, y, z} /.
  (Reduce[eqns, {y, z}] // ToRules)

{x, -3 + 2 x, 5 - 2 x}

Show[
 ContourPlot3D[Evaluate[eqns],
  {x, -5, 5}, {y, -10, 10}, {z, -10, 10}],
 ParametricPlot3D[parametricLine[x], {x, -5, 5},
  PlotStyle ->
   {Darker[Blue], AbsoluteThickness[4]}],
 AxesLabel -> {x, y, z}]


Bob Hanlon


On Sat, Jan 14, 2012 at 2:57 AM, Harry Har <harryhar800@gmail.com> wrote:
> Hi All,
>
> I'm a math senior high school teacher, and I wish to understand how
> using mathematica 7 to find "h" and the intersection point between the
> plane 6x-2y+z=11 which contains the line x-1 = (y+1)/2 = (z-3)/h. Also
> how to plot/show it visually in 3D graph.
>
> Many thank's.
>
> Harry.
>

[toc] | [standalone]


Back to top | Article view | comp.soft-sys.math.mathematica


csiph-web