Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]

Groups > comp.soft-sys.math.mathematica > #2105 > unrolled thread

Re: anything faster than Solve[] for solving sets of polynomial equations symbolically?

Back to article view | Back to comp.soft-sys.math.mathematica

Contents

  Re: anything faster than Solve[] for solving sets of polynomial equations symbolically? Maxim <m.r@inbox.ru> - 2011-05-04 23:48 +0000

#2105 — Re: anything faster than Solve[] for solving sets of polynomial equations symbolically?

On May 3, 4:47 am, dantimatter <goo...@dantimatter.com> wrote:
> Hi Everyone,
>
> I've got a set of equations and I'd really like to determine the number of real solutions in terms of the unspecified parameters.   The equations are:
>
> eqs = {-k5 x1 x3+k6 x4==0, k1 x1-k4 x2-2 k2 x2^2+2 k3 x3+k7 x4==0, k2 x2^2-k3 x3-k5 x1 x3+k6 x4==0,x1+x4-Xtot==0};
>
> where x1, x2, x3, and x4 are the variables I'd like to solve for and k1, k2, k3, k4, k5, k6, k7, and Xtot are real numbers that are greater than or equal to zero.   I've tried doing
>
> Solve[eqs, {x1, x2, x3, x4}, Reals]
>
> but after days and days I still have no solution.  Perhaps there's a faster or better way to do this?  
>
> Thanks,
> Dan

I'll deal with the case when the parameters are strictly greater than
0. This subsystem gives only one solution:

sols = Solve[eqs[[{1, 3, 4}]], {x1, x3, x4}]

So the number of solutions is determined by the remaining equation:

poly = Subtract @@ eqs[[2]] /. First@ sols // Together // Numerator

The number of real roots changes when crossing the discriminant, for a
cubic equation there simply will be three roots when the discriminant
is positive and one root when it's negative. This is the domain where
the system has three real solutions:

assums = And @@ Thread[{k1, k2, k3, k4, k5, k6, k7, Xtot} > 0];
Reduce[Discriminant[poly, x2] > 0 && assums] // FullSimplify[#,
assums]&

Out[15]= 9 k1 < k7 && (
  k3 k4^2 k6 (-27 k1^2 + 18 k1 k7 + k7^2 -
     Sqrt[(-9 k1 + k7)^3 (-k1 + k7)]))/(8 k1 k5 k7^3 Xtot^2) < k2 < (
  k3 k4^2 k6 (-27 k1^2 + 18 k1 k7 + k7^2 +
     Sqrt[(-9 k1 + k7)^3 (-k1 + k7)]))/(8 k1 k5 k7^3 Xtot^2)

Maxim Rytin
m.r@inbox.ru

[toc] | [standalone]

Back to top | Article view | comp.soft-sys.math.mathematica

csiph-web