Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #13940

Re: Problem in solving Differential Equation

From Bob Hanlon <hanlonr357@gmail.com>
Newsgroups comp.soft-sys.math.mathematica
Subject Re: Problem in solving Differential Equation
Date 2013-03-28 08:05 +0000
Message-ID <kj0tkd$iil$1@smc.vnet.net> (permalink)
References <20130306031441.3FE5E665F@smc.vnet.net>
Organization Time-Warner Telecom

Show all headers | View raw


Your DE can be solved exactly using DSolve.

Manipulate[
 eqn = x'[t] + lambda*x[t] == 0;
 sol[t_] = x[t] /. DSolve[
     {eqn, x[0] == 1/2}, x[t], t][[1]];
 ParametricPlot[
  {sol[t], sol'[t]},
  {t, 0, 25},
  PlotRange -> {{-0.1, 0.6}, {-3, 0.5}},
  Frame -> True,
  Axes -> False,
  FrameLabel -> (Style[#, "Courier", Bold, 16] & /@
     {x, Overscript[x, "."]}),
  AspectRatio -> 1,
  PlotStyle -> {{Red, AbsoluteThickness[2]}}],
 {{lambda, 0.5}, 0, 5, 0.01, Appearance -> "Labeled"}]


Bob Hanlon


On Wed, Mar 27, 2013 at 11:29 PM, Rahul Chakraborty
<rahul.6sept@gmail.com> wrote:
> Sir,
>
>  Can you kindly see what is the mistake in this code of mine. Its not
> giving me the output.
>
>
>  Clear [x,t];
> eqn=x'[t]+lambda*x[t]==0;
> Manipulate[[sol_]=NDSolve[{eqn,x[0]==1/2},x[t],{t,0,50}][[1]];
> ParametricPlot[Evaluate[{x[t]/.sol,D[x[t]/.sol,t]}],{t,0,25},PlotRange->{{-20,20},{-25,25}},Frame->True,Axes->False,FrameLabel->(Style[#,"Courier",Bold,16]&/@{"x",Overscript[x,"."]}),AspectRatio->1,PlotStyle->{{Red,AbsoluteThickness[2]}}],{{lambda,0.5},0,5}]
>
>
>
> Sincerely,
>
>  Rahul
>
> On 3/6/13, Bob Hanlon <hanlonr357@gmail.com> wrote:
>> Arguments to functions (e.g., Sin, Cos) must be enclosed in squares
>> brackets: Sin[x[t]] and Cos[x[t]]
>>
>> Clear[x];
>> \[Omega] = -2;
>> eqn =
>>   x''[t] + Sin[x[t]] - \[Omega]^2 Sin [x[t]] Cos[x[t]] == 0 //
>>    Simplify;
>> sol = NDSolve[
>>     {eqn, x[0] == 1/2, x'[0] == 0},
>>     x[t], {t, 0, 25}][[1]];
>> ParametricPlot[
>>  Evaluate[{x[t] /. sol, D[x[t] /. sol, t]}],
>>  {t, 0, 25},
>>  Frame -> True,
>>  Axes -> False,
>>  FrameLabel -> (Style[#, "Courier", Bold, 16] & /@
>>     {x, Overscript[x, "."]}),
>>  AspectRatio -> 1,
>>  PlotStyle -> {{Red, AbsoluteThickness[2]}}]
>> ParametricPlot[
>>  Evaluate[{t, x[t] /. sol}],
>>  {t, 0, 10},
>>  Frame -> True,
>>  Axes -> False,
>>  FrameLabel -> (Style[#, "Courier", Bold, 16] & /@
>>     {t, x}),
>>  AspectRatio -> .5,
>>  PlotStyle -> {{Green, AbsoluteThickness[3]}}]
>>
>>
>> Bob Hanlon
>>
>>
>> On Tue, Mar 5, 2013 at 10:14 PM, Rahul Chakraborty
>> <rahul.6sept@gmail.com> wrote:
>>> Dear all,
>>>
>>>  Following differential equation seems to have some error in coding by me.
>>> kindly let me know where i have gone wrong.
>>>
>>> Clear[x];
>>>  \[Omega]:=-2;
>>> eqn=x''[t]+ Sin  x[t]-\[Omega]^2  Sin  x[t]Cos  x[t]==0//Simplify;
>>> sol=NDSolve[{eqn,x[0]==1/2,x'[0]==0},x[t],{t,0,1000}][[1]]
>>> ParametricPlot[Evaluate[{x[t]/.sol,D[x[t]/.sol,t]}],{t,0,25},Frame->True,AxesLabel->{"x",Overscript[x,"."]},AspectRatio->1,PlotStyle->{{Red,AbsoluteThickness[2]}},TextStyle->{FontFamily->"Courier",FontWeight->"Bold",FontSize->16}]
>>> ParametricPlot[Evaluate[{t,x[t]/.sol}],{t,0,10},Frame->True,AxesLabel->{"t","x"},AspectRatio->.5,PlotStyle->{{Green,AbsoluteThickness[3]}},TextStyle->{FontFamily->"Courier",FontWeight->"Bold",FontSize->16}]
>>>
>>> Regards,
>>>
>>>  rahul
>>>
>>

Back to comp.soft-sys.math.mathematica | Previous | Next | Find similar | Unroll thread


Thread

Re: Problem in solving Differential Equation Bob Hanlon <hanlonr357@gmail.com> - 2013-03-28 08:05 +0000

csiph-web