Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #12203

Re: "Solve" on polynomial equality results in expressions

From Bob Hanlon <hanlonr357@gmail.com>
Newsgroups comp.soft-sys.math.mathematica
Subject Re: "Solve" on polynomial equality results in expressions
Date 2012-10-28 06:03 +0000
Message-ID <k6ihri$cju$1@smc.vnet.net> (permalink)
References <20121027034831.2AEC16893@smc.vnet.net>
Organization Time-Warner Telecom

Show all headers | View raw


x is strictly not a function of y since it is not single-valued. The
conditional expressions break the result into regions where it is
single-valued. The function is real in each of these regions.

sol = x /. Solve[y == 3 x^2 - 2 x^3, x, Reals] // ToRadicals

{ConditionalExpression[
     (1/2)*(1 +
          1/(1 - 2*y +
                 2*Sqrt[-y + y^2])^(1/3) +
          (1 - 2*y + 2*Sqrt[-y + y^2])^
            (1/3)), 0 < y < 1 ||
       y > 1 || y < 0],
   ConditionalExpression[
     1/2 - (1 + I*Sqrt[3])/
         (4*(1 - 2*y +
                 2*Sqrt[-y + y^2])^(1/3)) -
       (1/4)*(1 - I*Sqrt[3])*
         (1 - 2*y + 2*Sqrt[-y + y^2])^
           (1/3), 0 < y < 1],
   ConditionalExpression[
     1/2 - (1 - I*Sqrt[3])/
         (4*(1 - 2*y +
                 2*Sqrt[-y + y^2])^(1/3)) -
       (1/4)*(1 + I*Sqrt[3])*
         (1 - 2*y + 2*Sqrt[-y + y^2])^
           (1/3), 0 < y < 1]}

Plot[Evaluate[sol], {y, -3, 2},
 Frame -> True,
 Axes -> False,
 PlotStyle -> Evaluate[{#, AbsoluteThickness[2]} & /@ {Red, Blue, Green}],
 FrameLabel -> {"y", "x"}]

ContourPlot[y == 3 x^2 - 2 x^3,
 {y, -3, 2}, {x, -0.5, 2},
 AspectRatio -> 1/GoldenRatio,
 FrameLabel -> {"y", "x"}]

ParametricPlot[{3 x^2 - 2 x^3, x
  }, {x, -0.5, 2},
 PlotRange -> {{-3, 2}, {-0.5, 2}},
 Frame -> True, Axes -> False,
 AspectRatio -> 1/GoldenRatio,
 FrameLabel -> {"y", "x"}]


BobHanlon


On Fri, Oct 26, 2012 at 11:48 PM,  <coder0xff@gmail.com> wrote:
> If I do Solve[y==3x^2-2x^3,x] I get expressions containing imaginary parts. If I set the domain to the Reals (Solve[y==3x^2-2x^3,x,Reals]) then I got stuff like Root[y - 3 #1^2 + 2 #1^3 &, 2]. I know there's a solution using only reals (since the range and domain are both real, and complex math is performed as operations on reals after all) How can I get it to give me the actual solution using only reals?
>

Back to comp.soft-sys.math.mathematica | Previous | Next | Find similar | Unroll thread


Thread

Re: "Solve" on polynomial equality results in expressions Bob Hanlon <hanlonr357@gmail.com> - 2012-10-28 06:03 +0000

csiph-web