Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]
Groups > comp.soft-sys.math.mathematica > #12182
| From | Bob Hanlon <hanlonr357@gmail.com> |
|---|---|
| Newsgroups | comp.soft-sys.math.mathematica |
| Subject | Re: Fourier Transform of a "step" function |
| Date | 2012-10-26 03:34 +0000 |
| Message-ID | <k6d0c8$25r$1@smc.vnet.net> (permalink) |
| References | <20121025054335.0BFEB68B5@smc.vnet.net> |
| Organization | Time-Warner Telecom |
f[x_] = Piecewise[
{{a + b x + c x^2, 0 < x < 20}}, 0];
g[w_] = FourierTransform[f[x], x, w] //
FullSimplify
-((1/(Sqrt[2*Pi]*w^3))*
(I*(2*c - w*(I*b + a*w) +
E^(20*I*w)*(-2*c +
I*(b + 40*c)*w +
(a + 20*(b + 20*c))*w^2))))
f2[x_] = InverseFourierTransform[g[w], w, x]
(1/2)*(a + x*(b + c*x))*
(Sign[20 - x] + Sign[x])
f2 differs from the original function only on the step transitions
Simplify[f2[x], #] & /@
{x < 0, x == 0, 0 < x < 20, x == 20, x > 20}
{0, a/2, a + x*(b + c*x),
(1/2)*(a + 20*(b + 20*c)), 0}
f2 has the same Fourier transform as the original function
g[w] == FourierTransform[f2[x], x, w]
True
Bob Hanlon
On Thu, Oct 25, 2012 at 1:43 AM, <etaghtron@gmail.com> wrote:
> Dear Group,
>
> I am new to Mathematica. So question might be naive.
>
> I have a function, which is defined in this form
>
> F(x) = a + b x + c x^2(0 < x < x0)
> F(x) = 0 (x > x0)
>
> This function is simple. However, its Fourier transform is not straightforward due to the limits of the function. I probably can do it manually, but I have a few other functions that are more complex than this one, which also requires Fourier transform. So I'd like to know if Mathematica can handle this.
>
> If you could please shed some light on this, I would be really grateful.
>
> Best Regards,
> Frank
>
Back to comp.soft-sys.math.mathematica | Previous | Next | Find similar | Unroll thread
Re: Fourier Transform of a "step" function Bob Hanlon <hanlonr357@gmail.com> - 2012-10-26 03:34 +0000
csiph-web