Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.soft-sys.math.mathematica > #9713

Re: NIntegrate about singular point

From danl@wolfram.com
Newsgroups comp.soft-sys.math.mathematica
Subject Re: NIntegrate about singular point
Date 2012-04-20 11:49 +0000
Organization Steven M. Christensen and Associates, Inc and MathTensor, Inc.
Message-ID <jmrigf$lep$1@smc.vnet.net> (permalink)
References <jmjf8p$89v$1@smc.vnet.net>

Show all headers | View raw


On Tuesday, April 17, 2012 5:05:13 AM UTC-5, bowlderster wrote:
> Hello, all.
> I am dealing with an integral as following
> 
> h = 1
> m = 1
> n = 1
> t = 1
> k = 4.0269
> kk = 4.0284
> Plot[x^(m + n - 1)/(x*Sinh[x*h] -
>      kk*Cosh[x*h])*((x +
>        kk)*((-1)^(m + n)*Exp[x*(2.*(-0.2) + h)] - ((-1)^m + (-1)^n)*
>         Exp[-x*h]) + (x - kk)*Exp[-x*(2.*(-0.2) + h)]), {x, 0, 40}]
> NIntegrate[
>  x^(m + n - 1)/(x*Sinh[x*h] -
>      kk*Cosh[x*h])*((x +
>        kk)*((-1)^(m + n)*Exp[x*(2.*(-0.2) + h)] - ((-1)^m + (-1)^n)*
>         Exp[-x*h]) + (x - kk)*Exp[-x*(2.*(-0.2) + h)]), {x, 0,
>   Infinity}]
> 
> It has a singular point when the denominator is zero.
> At begining, I try to solve it in another system, yet with Nan result.
> 
> It is the first time for me to use Mathematica.
> Can it solve the integral with singular point?
> 
> Thanks for your help

It's not an integrable singularity. To see this, find poles (there is only one, actually), and check the series expansions there.

In[208]:= h = 1; 
m = 1; 
n = 1; 
t = 1; 
k = 40269/10000; 
kk = 40284/10000; 
expr = Rationalize[(x^(m + n - 1)/(x*Sinh[x*h] - kk*Cosh[x*h]))*
       ((x + 
        kk)*((-1)^(m + n)*Exp[x*(2.*-0.2 + h)] - ((-1)^m + (-1)^n)*
         Exp[(-x)*h]) + 
          (x - kk)*Exp[(-x)*(2.*-0.2 + h)])]

Out[214]= (x*((-(10071/2500) + x)/
      E^((3*x)/5) + (2/E^x + E^((3*x)/5))*(10071/2500 + x)))/
   (-((10071*Cosh[x])/2500) + x*Sinh[x])

In[218]:= poles = x /. Solve[Denominator[expr] == 0 && x >= 0, x]

Out[218]= {Root[{10071 - 2500*#1 + (10071 + 2500*#1)/E^(2*#1) & , 
       4.0309413727078305519742154202340325203130636422539920318199`\
20.60201996114937}]}

In[221]:= Quiet[series = (Series[expr, {x, #1, 1}] & ) /@ poles]; 

In[223]:= N[Normal[series]]

Out[223]= {-0.35541518014768414 + 
  12.935900519888259/(-4.03094137270783 + x) - 
     0.49281698406801144*(-4.03094137270783 + x)}

We have a 1/(x-pole) singularity, ergo no convergence.

Daniel Lichtblau
Wolfram Research

Back to comp.soft-sys.math.mathematica | Previous | Next — Previous in thread | Find similar | Unroll thread


Thread

NIntegrate about singular point bowlderster <bowlderster@gmail.com> - 2012-04-17 10:05 +0000
  Re: NIntegrate about singular point A Retey <awnl@gmx-topmail.de> - 2012-04-18 07:54 +0000
    Re: NIntegrate about singular point bowlderster <bowlderster@gmail.com> - 2012-04-19 07:54 +0000
  Re: NIntegrate about singular point danl@wolfram.com - 2012-04-18 07:56 +0000
  Re: NIntegrate about singular point danl@wolfram.com - 2012-04-20 11:49 +0000

csiph-web