Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]
Groups > comp.soft-sys.math.mathematica > #9234
| From | Bob Hanlon <hanlonr357@gmail.com> |
|---|---|
| Newsgroups | comp.soft-sys.math.mathematica |
| Subject | Re: Piecewise ColorFunction |
| Date | 2012-03-26 06:46 +0000 |
| Organization | Steven M. Christensen and Associates, Inc and MathTensor, Inc. |
| Message-ID | <jkp3ba$kto$1@smc.vnet.net> (permalink) |
| References | <201203250517.AAA12261@smc.vnet.net> |
>From the documentation: "With the usual default setting
ColorFunctionScaling -> True, all arguments supplied to func are
scaled to lie in the range 0 to 1."
ClearAll[f];
f[y_] = Piecewise[{{Green, y < 0}, {Red, y >= 0}}];
Plot[Sin[x], {x, 0, 4 Pi},
PlotStyle -> Thick,
ColorFunction -> Function[{x, y}, f[y - 1/2]]]
Plot[Sin[x], {x, 0, 4 Pi},
PlotStyle -> Thick,
ColorFunction -> Function[{x, y}, f[y]],
ColorFunctionScaling -> False]
ClearAll[f];
f = Piecewise[{{Green, #2 < 0}, {Red, #2 >= 0}}] &;
Plot[Sin[x], {x, 0, 4 Pi},
PlotStyle -> Thick,
ColorFunction -> f,
ColorFunctionScaling -> False]
Bob Hanlon
On Sun, Mar 25, 2012 at 1:17 AM, Hugh Goyder
<h.g.d.goyder@cranfield.ac.uk> wrote:
> The first example below works to give a plot style with colours that vary with y-values. I then try to define a Piecewise function for the colour and this does not work. Am I doing something wrong? Thanks for any assistance.
>
> Plot[Sin[x], {x, 0, 4 Pi}, PlotStyle -> Thick,
> ColorFunction -> Function[{x, y}, ColorData["NeonColors"][y]]]
>
>
> ClearAll[f];
> f[x_, y_] := Piecewise[{{Green, y < 0}, {Red, y >= 0}}]
>
>
> Plot[Sin[x], {x, 0, 4 Pi}, PlotStyle -> Thick, ColorFunction -> f]
>
Back to comp.soft-sys.math.mathematica | Previous | Next | Find similar | Unroll thread
Re: Piecewise ColorFunction Bob Hanlon <hanlonr357@gmail.com> - 2012-03-26 06:46 +0000
csiph-web