Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]
Groups > comp.soft-sys.math.mathematica > #6571
| From | Gary <gpalmerlv@gmail.com> |
|---|---|
| Newsgroups | comp.soft-sys.math.mathematica |
| Subject | Re: Problem displaying user-created .cdf files |
| Date | 2011-11-20 10:47 +0000 |
| Organization | Steven M. Christensen and Associates, Inc and MathTensor, Inc. |
| Message-ID | <jaalrc$1b0$1@smc.vnet.net> (permalink) |
| References | <ja2pvl$mak$1@smc.vnet.net> <ja85eh$iks$1@smc.vnet.net> |
OK, I discovered the Open Option feature also resides in the Format
menu, so I do have access to the options. But the drama continues. I
restored the visible brackets to the .nb file and I find that
evaluation now produces a fine looking but non-functioning Manipulate
plot. To the best of my knowledge, I changed nothing in the code
itself, which formerly produced a notebook plot with working sliders.
I wonder if there is an option that I have set to the wrong value.
(* Rotation on arbitrary axes *)
(* Note that in Mathematica 3D graphics, the standard viewpoint has \
the x axis nearly horizontal and the y axis nearly vertical. *)
Clear[xV, yV, zV, originC, vDiskAxis]
(* Cartesian frame and origin *)
xV = {1, 0, 0};
yV = {0, 1, 0};
zV = {0, 0, 1};
originC = {0, 0, 0};
(* Line, arrow, disk functions defined to use vector parameters. *)
(* \
o, origin; vAxis, axis; len, cylinder length; r, cylinder radius *)
vLine[o_, v_, len_] := Line[{o, o + len*Normalize[v]}];
vArrow[o_, v_, len_] := Arrow[{o, o + len*Normalize[v]}];
vCylinder[o_, vAxis_, len_, r_] :=
Cylinder[{o, o + len*Normalize[vAxis]}, r];
(* len in vFrame3D is length from origin; total length = 2*len *)
vFrame3D[len_] := {
Thick, Black,
vLine[-len*Normalize[xV], xV, 2*len],
vLine[-len*Normalize[yV], yV, 2*len],
vLine[-len*Normalize[zV], zV, 2*len],
Text[Style["X", 16, Bold], (11/10)*len*Normalize[xV ]],
Text[Style["Y", 16, Bold], (11/10)*len*Normalize[yV ]],
Text[Style["Z", 16, Bold], (11/10)*len*Normalize[zV ]]
};
vDiskAxis = {1, 1, 1};
demoObjects = {
Thick, Red,
vArrow[originC, xV, 5],
vArrow[originC, yV, 5],
vArrow[originC, zV, 5],
Thick, Orange, vArrow[originC, vDiskAxis, 5],
Magenta, vCylinder[originC, vDiskAxis, .2, .5],
Blue, Specularity[1], Sphere[{2, 3, 2}, .5]
};
Manipulate[
Graphics3D[
{
vFrame3D[5], (* frame does not rotate *)
Rotate[
Rotate[
Rotate[
Rotate[
demoObjects,
w, vDiskAxis, originC
],
x, {1, 0, 0}, originC
],
y, {0, 1, 0}, originC
],
z, {0, 0, 1}, originC
]
},
(* Parameters and ranges for Graphics3D[] *)
ViewPoint -> {2, 3/4, .2},
Background -> LightYellow,
Boxed -> False,
ImageSize -> Full,
PlotRange -> {{-5, 5}, {-5, 6}, {-5, 5}}
(* Alert: To avoid box shifting,
specify PlotRange for x,y,and z axis. *)
],
(* Parameters and ranges for Manipulate[] *)
Style["\n\n\nROTATIONS\n", 16, Bold],
Style["on disk axis", 16, Bold], {{w, 0}, 0, 2*Pi, 2*Pi/90},
Style["on x axis", 16, Bold], {{x, 0}, 0, 2*Pi, 2*Pi/90},
Style["on y axis", 16, Bold], {{y, 0}, 0, 2*Pi, 2*Pi/90},
Style["on z axis", 16, Bold], {{z, 0}, 0, 2*Pi, 2*Pi/90},
ContentSize -> 425,
ControlPlacement -> Right,
SaveDefinitions -> True
]
On Nov 19, 3:54 am, Gary <gpalme...@gmail.com> wrote:
> I should add to the previous, that not only is the Open Option
> Inspector button grayed out, but the entire Preferences dialog appears
> to be frozen.
Back to comp.soft-sys.math.mathematica | Previous | Next — Previous in thread | Find similar | Unroll thread
Re: Problem displaying user-created .cdf files John Fultz <jfultz@wolfram.com> - 2011-11-17 11:08 +0000
Re: Problem displaying user-created .cdf files Gary <gpalmerlv@gmail.com> - 2011-11-19 11:54 +0000
Re: Problem displaying user-created .cdf files Gary <gpalmerlv@gmail.com> - 2011-11-19 11:54 +0000
Re: Problem displaying user-created .cdf files Gary <gpalmerlv@gmail.com> - 2011-11-20 10:36 +0000
Re: Problem displaying user-created .cdf files Gary <gpalmerlv@gmail.com> - 2011-11-20 10:45 +0000
Re: Problem displaying user-created .cdf files Gary <gpalmerlv@gmail.com> - 2011-11-20 10:47 +0000
csiph-web