Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]

Groups > comp.soft-sys.math.mathematica > #3116

Re: Problem with Position

Show all headers | View raw

Perhaps the numbers have more decimal places than what is displayed and you
 need to round to the precision of the index key.

choices = {0.123456, 0.654321, 0.785398};

data = Table[{
    RandomChoice[choices] + 10^-7*Random[],
    RandomReal[], RandomReal[]}, {10}];

Flatten@
 Position[N[Round[data[[All, 1]], 10^-6]],
  0.785398]

{2, 5, 6, 9}

Flatten@
   Position[N[Round[data[[All, 1]], 10^-6]], #] & /@
 choices

{{1, 3, 4, 8}, {7, 10}, {2, 5, 6, 9}}

Alternatively,

Flatten@
 Position[data[[All, 1]],
  _?(Abs[# - 0.785398] < 10^-6 &)]

{2, 5, 6, 9}

Table[
 Flatten@Position[data[[All, 1]],
   _?(Abs[# - c] < 10^-6 &)],
 {c, choices}]

{{1, 3, 4, 8}, {7, 10}, {2, 5, 6, 9}}


Bob Hanlon

---- "Dominic W=C3=B6rner" <dominic.woerner@mpi-hd.mpg.de> wrote:

=============
Hi,

I have to import data from a csv file. And I get a structure data[[rows]] ={first, second,...}.
Now I want to find the rows in which, say the first entry has a specific values.
By just looking at the data there are for example entries with value 0.785398.
But when I try Flatten@Position[data[[All,1]],0.785398] or with ToString[0.785398] I just get {}

What's the problem here?

Best,
Dominic

Back to comp.soft-sys.math.mathematica | Previous | Next | Find similar | Unroll thread

Thread

Re: Problem with Position Bob Hanlon <hanlonr@cox.net> - 2011-06-16 08:00 +0000

csiph-web