Groups > comp.soft-sys.math.mathematica > #2969

Re: plotting contours on a sphere [CORRECTION]

From	Bob Hanlon <hanlonr@cox.net>
Newsgroups	comp.soft-sys.math.mathematica
Subject	Re: plotting contours on a sphere [CORRECTION]
Date	2011-06-06 10:23 +0000
Organization	Steven M. Christensen and Associates, Inc and MathTensor, Inc.
Message-ID	<isi9rb$ltr$1@smc.vnet.net> (permalink)

Show all headers | View raw

This removes the boundary artifact.

p3 = SphericalPlot3D[1, {\[Phi], 0, Pi}, {\[Theta], 0, 2 Pi},
  ColorFunctionScaling -> False,
  ColorFunction -> Function[{x, y, z, \[Theta], \[Phi], r},
    ColorData["TemperatureMap"]
     [Rescale[f[\[Phi], \[Theta]], {-1, 1}]]],
  Mesh -> 9,
  MeshFunctions ->
   {Function[{x, y, z, \[Theta], \[Phi], r}, 
     f[\[Phi], \[Theta]]]},
  BoundaryStyle -> Transparent]


Bob Hanlon

---- Bob Hanlon <hanlonr@cox.net> wrote: 

=============

p3 = SphericalPlot3D[1, {\[Phi], 0, Pi}, {\[Theta], 0, 2 Pi},
  ColorFunctionScaling -> False,
  ColorFunction -> Function[{x, y, z, \[Theta], \[Phi], r},
    ColorData["TemperatureMap"]
     [Rescale[f[\[Phi], \[Theta]], {-1, 1}]]],
  Mesh -> 9,
  MeshFunctions ->
   {Function[{x, y, z, \[Theta], \[Phi], r}, 
     f[\[Phi], \[Theta]]]}]


Bob Hanlon

---- J Davis <texasautiger@gmail.com> wrote: 

=============
I would like to plot the contours of a given function f on the surface
of a sphere.

More specifically, I'd like to "wrap" the contours in p2 below onto
the surface of the sphere in p3.

f[\[Theta]_, \[Phi]_] = Sin[\[Theta] + \[Phi]];
p1 = Plot3D[f[\[Theta], \[Phi]], {\[Theta], 0, 2 Pi}, {\[Phi], 0, Pi},
    PlotRange -> All, AxesLabel -> {\[Theta], \[Phi]},
   ColorFunction -> ColorData["TemperatureMap"]];
p2 = ContourPlot[
   f[\[Theta], \[Phi]], {\[Theta], 0, 2 Pi}, {\[Phi], 0, Pi},
   PlotRange -> All, FrameLabel -> {\[Theta], \[Phi]},
   ColorFunction -> ColorData["TemperatureMap"]];
p3 = SphericalPlot3D[1, {\[Phi], 0, Pi}, {\[Theta], 0, 2 Pi},
   ColorFunctionScaling -> False,
   ColorFunction ->
    Function[{x, y, z, \[Theta], \[Phi], r},
     ColorData["TemperatureMap"][
      Rescale[f[\[Phi], \[Theta]], {-1, 1}]]]];
GraphicsRow[{p1, p2, p3}, ImageSize -> 750]

Thanks in advance for any insight you can offer.

Best,
John

Back to comp.soft-sys.math.mathematica | Previous | Next | Find similar | Unroll thread

Thread

Re: plotting contours on a sphere [CORRECTION] Bob Hanlon <hanlonr@cox.net> - 2011-06-06 10:23 +0000

csiph-web