Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]

Groups > comp.soft-sys.math.mathematica > #2904

Re: Portfolio Optimization

Show all headers | View raw

Mathematica was correct, when it said "{{0.00408844}} is not a number". It  
isn't.

Here's Excel's low function value, without negative weights:

covariants = {{0.000572843, 0.000223023, 0.000109176}, {0.000223023,
     0.000387437, 0.0000987402}, {0.000109176, 0.0000987402,
     0.007320276}};

(*Asset Weights Vector*)
weights = {w1, w2, w3};

NMinimize[{weights.covariants.weights,
    Total@weights == 1}, weights]

{0.000327596, {w1 -> 0.309102, w2 -> 0.659653, w3 -> 0.0312441}}

or

NMinimize[{weights.covariants.weights,
    Total@weights == 1, Thread[weights >= 0]}, weights]

{0.000327596, {w1 -> 0.309102, w2 -> 0.659653, w3 -> 0.0312441}}

or

Minimize[{weights.covariants.weights,
   Total@weights == 1, Thread[weights >= 0]}, weights]

{0.000327596, {w1 -> 0.309102, w2 -> 0.659653, w3 -> 0.0312441}}

weights.(covariants.weights) - (weights.covariants).weights

0

Bobby

On Thu, 02 Jun 2011 06:17:22 -0500, Priyan Fernando  
<priyan.fernando@gmail.com> wrote:

> Hi!
>
> I am trying to run a portfolio optimizer in Mathematica. That is,  
> minimising
> the variance of a portfolio of assets.
>
> (* Variance Covariance Matrix *)
> Covariants = {{0.000572843, 0.000223023, 0.000109176}, {0.000223023,
>    0.000387437, 0.0000987402}, {0.000109176, 0.0000987402,
>    0.007320276}}
>
> (* Asset Weights Vector*)
> weights = Transpose[{{w1}, {w2}, {w3}}]
>
> (* Optimize Portfolio Variance*)
> NMinimize[{weights.Covariants.Transpose[weights],
>   w1 + w2 + w3 == 1}, {w1, w2, w3}]
>
> The output Mathematica throws is as follows:
> *NMinimize::nnum: "The function value {{0.00408844}} is not a number at
> {w1,w2,w3} = {-0.63531,0.918621,0.716689}. "*
>
> However if I program the same optimization in Excel (using Solver to find
> optimal weights) I see the weights should be {0.309102831, 0.659653054,
> 0.031244115} as this gives a lower portoflio variance of 0.0003276.
>
> Does anyone know why Mathematica is giving me the wrong answer? And, why  
> is
> it saying the funcion value is not a number?
>
> Thanks for your all your comments,
> Priyan.
>
>


-- 
DrMajorBob@yahoo.com

Back to comp.soft-sys.math.mathematica | Previous | Next | Find similar | Unroll thread

Thread

Re: Portfolio Optimization DrMajorBob <btreat1@austin.rr.com> - 2011-06-02 23:10 +0000

csiph-web