Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.lang.clipper.visual-objects > #7738 > unrolled thread

BBrowser tips please, moving columns

Started byMartin <spam@spam.spam>
First post2015-02-11 15:52 +0000
Last post2015-02-15 23:21 -0800
Articles 3 — 3 participants

Back to article view | Back to comp.lang.clipper.visual-objects


Contents

  BBrowser tips please, moving columns Martin <spam@spam.spam> - 2015-02-11 15:52 +0000
    Re: BBrowser tips please, moving columns Paulo Oliveira <paulo@clipinfor.com> - 2015-02-12 03:47 -0800
    Re: BBrowser tips please, moving columns Mathias <mathias.hakansson@consultec.se> - 2015-02-15 23:21 -0800

#7738 — BBrowser tips please, moving columns

FromMartin <spam@spam.spam>
Date2015-02-11 15:52 +0000
SubjectBBrowser tips please, moving columns
Message-ID<mbftpe$l7u$1@dont-email.me>
Hello

Are there any good samples of bbrowser code for saving and restoring 
column positions and widths so a user can change them at will?

Thanks


Martin

[toc] | [next] | [standalone]


#7741

FromPaulo Oliveira <paulo@clipinfor.com>
Date2015-02-12 03:47 -0800
Message-ID<4da66b8d-5152-4413-9694-ccad4c7f3ceb@googlegroups.com>
In reply to#7738
Hi Martin,

I use some code like this:

I use a SqlTable (ConfBrowser) to store the Fields and Widths of a bbrowser also the user login and the parent window.

The METHOD ColocaColunas(), is in the PostInit method of the Window.

METHOD Close (oEvent) CLASS JanelaBase
	LOCAL i AS SHORT
	LOCAL oColumn AS bDataColumn
	LOCAL cFields AS STRING
	LOCAL cWidths AS STRING
	LOCAL oConfBrowser AS ConfBrowser
	
	// Close has to re-set the window to non-modal if it's still modal.
	IF _lModal
		SELF:SetModal (FALSE)
	ENDIF

	SUPER:close (oEvent)
	IF !POGetAppObject():lCloseApp
		oConfBrowser:=ConfBrowser{POGetAppObject():cUtilizador,SELF:cClassName}
	
		cFields :=NULL_STRING
		cWidths :=NULL_STRING
	
		FOR i:=1 UPTO ALen(SELF:oDCbBDetalheBase:ColumnOpenList)
			oColumn:=SELF:oDCbBDetalheBase:ColumnOpenList[i]
			IF !Empty(Symbol2String(oColumn:FieldSym))
				cFields +=Symbol2String(oColumn:FieldSym)+"|"
				cWidths +=NTrim(oColumn:Width)+"|"
			ENDIF	
		NEXT i
	
		IF oConfBrowser:RecCount=0			
			oConfBrowser:Append()
			oConfBrowser:FIELDPUT(#CUTENTE,AllTrim(POGetAppObject():cUtilizador))
			oConfBrowser:FIELDPUT(#CCLASS,AllTrim(SELF:cClassName))
		ENDIF	
		oConfBrowser:FIELDPUT(#CCOLUNAS,cFields)
		oConfBrowser:FIELDPUT(#CTAMANHOS,cWidths)
		oConfBrowser:Commit()
		oConfBrowser:Close()
	ENDIF	
	RETURN TRUE

METHOD ColocaColunas() CLASS JanelaBase	
	LOCAL cFields AS STRING
	LOCAL cWidths AS STRING
	LOCAL aFields AS ARRAY
	LOCAL aWidths AS ARRAY
	LOCAL oColumn AS bDataColumn
	LOCAL i AS SHORT
	LOCAL oConfBrowser AS ConfBrowser
	
BEGIN SEQUENCE	
	oConfBrowser:=ConfBrowser{POGetAppObject():cUtilizador,SELF:cClassName}
	oConfBrowser:NullAsBlank:=TRUE
	IF oConfBrowser:RecCount>0	
		aFields:=ClipString2Array(oConfBrowser:FIELDGET(#CCOLUNAS),"|")
   		aWidths:=ClipString2Array(oConfBrowser:FIELDGET(#CTAMANHOS),"|")
   	ELSE
		BREAK
	ENDIF

	IF ALen(aFields)!=ALen(SELF:oDCbBDetalheBase:ColumnOpenList).or.Val(aWidths[ALen(aWidths)])=4
		cFields :=NULL_STRING
  		cWidths :=NULL_STRING
		FOR i:=1 UPTO ALen(SELF:oDCbBDetalheBase:ColumnOpenList)
	   		oColumn:=SELF:oDCbBDetalheBase:ColumnOpenList[i]
			cFields +=Symbol2String(oColumn:FieldSym)+"|"
	   		cWidths +=NTrim(oColumn:Width)+"|"
	  	NEXT i
	 	oConfBrowser:FIELDPUT(#CCOLUNAS,cFields)
		oConfBrowser:FIELDPUT(#CTAMANHOS,cWidths)
		oConfBrowser:Commit()
	ENDIF	
END SEQUENCE

  	IF oConfBrowser:RecCount>0
  		cFields:=oConfBrowser:FIELDGET(#CCOLUNAS)
	  	cWidths:=oConfBrowser:FIELDGET(#CTAMANHOS)
	   	aFields:=ClipString2Array(cFields,"|")
   		aWidths:=ClipString2Array(cWidths,"|")
	   FOR i:=1 UPTO ALen(aFields)
	    IF !Empty(aFields[i]).and.String2Symbol(aFields[i])!=#Check
		 	oColumn := SELF:oDCbBDetalheBase:GetColumn(String2Symbol(aFields[i]))
			oColumn:Width:=Val(aWidths[i])
		 	SELF:oDCbBDetalheBase:CloseColumn(oColumn,TRUE)
			SELF:oDCbBDetalheBase:OpenColumn(oColumn,i)
	    ENDIF
	   NEXT i
  	ENDIF
	oConfBrowser:Close()
  	SELF:oDCbBDetalheBase:AdjustAutoWidthColumn(TRUE,TRUE)
	SELF:oDCbBDetalheBase:CurrentColumn:=SELF:oDCbBDetalheBase:Freeze+1

I hope this help you.

Paulo
		

[toc] | [prev] | [next] | [standalone]


#7744

FromMathias <mathias.hakansson@consultec.se>
Date2015-02-15 23:21 -0800
Message-ID<276c9608-cbf1-42f5-a1ad-2987a7e74eab@googlegroups.com>
In reply to#7738
Den onsdag 11 februari 2015 kl. 16:51:48 UTC+1 skrev Martin:
> Hello
> 
> Are there any good samples of bbrowser code for saving and restoring 
> column positions and widths so a user can change them at will?
> 
> Thanks
> 
> 
> Martin

Hi Martin,

this is my way of doing it. The code is placed in a browser class and a datawindow classs that I Always inherit from.

https://groups.google.com/forum/?hl=sv&fromgroups#!searchin/comp.lang.clipper.visual-objects/GetDataColumnPositionsAndSizes/comp.lang.clipper.visual-objects/kfa9YmIgXDQ/rsFEQw_h6JoJ

/Mathias

[toc] | [prev] | [standalone]


Back to top | Article view | comp.lang.clipper.visual-objects


csiph-web