Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]
Groups > comp.lang.clipper.visual-objects > #7006 > unrolled thread
| Started by | "Claus Wagner" <cwagner@laufwerk.net> |
|---|---|
| First post | 2014-06-26 14:57 +0200 |
| Last post | 2016-03-15 07:34 -0700 |
| Articles | 6 — 4 participants |
Back to article view | Back to comp.lang.clipper.visual-objects
urlencode "Claus Wagner" <cwagner@laufwerk.net> - 2014-06-26 14:57 +0200
Re: urlencode Karl Wochele <kw@e©os-system.dot.de> - 2014-06-26 15:08 +0200
Re: urlencode Sherlock <sherlock@sherlock.com.au> - 2014-06-26 06:29 -0700
Re: urlencode Karl Wochele <kw@e©os-system.dot.de> - 2014-06-27 08:27 +0200
Re: urlencode "Claus Wagner" <cwagner@laufwerk.net> - 2014-06-27 09:53 +0200
Re: urlencode moshe attia <attiamx@gmail.com> - 2016-03-15 07:34 -0700
| From | "Claus Wagner" <cwagner@laufwerk.net> |
|---|---|
| Date | 2014-06-26 14:57 +0200 |
| Subject | urlencode |
| Message-ID | <loh5c8$c52$1@news.albasani.net> |
Hi, I need a possibility to urlencode Strings. Any hints? Thank you, Claus Wagner
[toc] | [next] | [standalone]
| From | Karl Wochele <kw@e©os-system.dot.de> |
|---|---|
| Date | 2014-06-26 15:08 +0200 |
| Message-ID | <c12k9nF9s85U1@mid.individual.net> |
| In reply to | #7006 |
Hi Claus,
here are the functions I use:
FUNCTION UrlEncode(cText)
LOCAL cEncode AS STRING
LOCAL pIn AS BYTE PTR
LOCAL nLen AS DWORD
LOCAL pOut AS BYTE PTR
LOCAL pTemp AS BYTE PTR
LOCAL n AS DWORD
LOCAL vc AS DWORD
LOCAL nOut AS DWORD
LOCAL cHex AS STRING
LOCAL nAlloc AS DWORD
pIn := PTR(_CAST, StringAlloc(cText))
nLen := SLen(cText)
nAlloc := Max(nLen*3,10)
pOut := MemAlloc(nAlloc)
FOR n := 1 TO nLen
IF nOut >= nAlloc-3
nAlloc += Min(nLen,1024)
pTemp := MemAlloc(nAlloc)
MemCopy(pTemp,pOut,nOut)
MemFree(pOut)
pOut := pTemp
ENDIF
vc := pIn[n]
DO CASE
CASE vc = 32
nOut += 1
pOut[nOut] := 43 //Asc("+")
CASE InList(vc,Asc("!"),;
Asc("#"),;
Asc("$"),;
Asc("%"),;
Asc("&"),;
Asc("'"),;
Asc("("),;
Asc(")"),;
Asc("*"),;
Asc("+"),;
Asc(","),;
Asc("/"),;
Asc(":"),;
Asc(";"),;
Asc("="),;
Asc("?"),;
Asc("@"),;
Asc("["),;
Asc("]"))
nOut += 1
pOut[nOut] := Asc("%")
cHex := Lower(BaseToBase(NTrim(vc),10,16,2))
nOut += 1
pOut[nOut] := Asc(Left(cHex,1))
nOut += 1
pOut[nOut] := Asc(Right(cHex,1))
OTHERWISE
nOut += 1
pOut[nOut] := vc
ENDCASE
NEXT n
MemFree(pIn)
cEncode := Mem2String(pOut,DWORD(nOut))
MemFree(pOut)
RETURN cEncode
FUNCTION UrlDecode(cText)
LOCAL cDecode AS STRING
LOCAL nOut AS DWORD
LOCAL pIn AS BYTE PTR
LOCAL nLen AS DWORD
LOCAL pOut AS BYTE PTR
LOCAL pTemp AS BYTE PTR
LOCAL n AS DWORD
LOCAL vc AS DWORD
LOCAL cHex AS STRING
LOCAL nAlloc AS DWORD
pIn := PTR(_CAST, StringAlloc(cText))
nLen := SLen(cText)
nAlloc := Max(nLen,10)
pOut := MemAlloc(nAlloc)
FOR n := 1 TO nLen
IF nOut >= nAlloc-3
nAlloc += Min(nLen,1024)
pTemp := MemAlloc(nAlloc)
MemCopy(pTemp,pOut,nOut)
MemFree(pOut)
pOut := pTemp
ENDIF
vc := pIn[n]
DO CASE
CASE vc = Asc("%")
n += 1
vc := pIn[n]
cHex := CHR(vc)
n += 1
vc := pIn[n]
cHex += CHR(vc)
nOut += 1
pOut[nOut] := Val(BaseToBase(cHex,16,10,3))
CASE vc = Asc("+")
nOut += 1
pOut[nOut] := 32 //Asc(" ")
OTHERWISE
nOut += 1
pOut[nOut] := vc
ENDCASE
NEXT n
MemFree(pIn)
cDecode := Mem2String(pOut,DWORD(nOut))
MemFree(pOut)
RETURN cDecode
HTH
Karl
Am 26.06.2014 14:57, schrieb Claus Wagner:
> Hi,
>
> I need a possibility to urlencode Strings.
> Any hints?
>
> Thank you,
> Claus Wagner
>
[toc] | [prev] | [next] | [standalone]
| From | Sherlock <sherlock@sherlock.com.au> |
|---|---|
| Date | 2014-06-26 06:29 -0700 |
| Message-ID | <e85dac7e-364b-4e05-a9a2-e2ef2e16ba74@googlegroups.com> |
| In reply to | #7006 |
snip[ I need a possibility to urlencode Strings. ]
FUNCTION UrlEncodeString( cRawString AS STRING ) AS STRING
LOCAL cURLEncodeOut := "" AS STRING
LOCAL cOneChar AS STRING
LOCAL xx, dwLength AS DWORD
dwLength := SLen(cRawString)
FOR xx := 1 UPTO dwLength
cOneChar := SubStr(cRawString, xx, 1)
//
IF At( cOneChar, "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789-_.~" ) > 0
cURLEncodeOut += cOneChar
ELSE
cURLEncodeOut += "%" + right(AsHexString(Asc(cOneChar)),2)
ENDIF
NEXT
//
RETURN cURLEncodeOut
[toc] | [prev] | [next] | [standalone]
| From | Karl Wochele <kw@e©os-system.dot.de> |
|---|---|
| Date | 2014-06-27 08:27 +0200 |
| Message-ID | <c14h68FlunsU1@mid.individual.net> |
| In reply to | #7008 |
this is close to what I had in earlier days, but if you export thousands of products to a webshop with json-strings, vo-strings are too slow. Using BYTE-Pointers speeds it up extremely... Am 26.06.2014 15:29, schrieb Sherlock: > snip[ I need a possibility to urlencode Strings. ] > > FUNCTION UrlEncodeString( cRawString AS STRING ) AS STRING > > LOCAL cURLEncodeOut := "" AS STRING > LOCAL cOneChar AS STRING > LOCAL xx, dwLength AS DWORD > > dwLength := SLen(cRawString) > FOR xx := 1 UPTO dwLength > cOneChar := SubStr(cRawString, xx, 1) > // > IF At( cOneChar, "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789-_.~" ) > 0 > cURLEncodeOut += cOneChar > ELSE > cURLEncodeOut += "%" + right(AsHexString(Asc(cOneChar)),2) > ENDIF > NEXT > // > RETURN cURLEncodeOut >
[toc] | [prev] | [next] | [standalone]
| From | "Claus Wagner" <cwagner@laufwerk.net> |
|---|---|
| Date | 2014-06-27 09:53 +0200 |
| Message-ID | <loj7ui$9h5$1@news.albasani.net> |
| In reply to | #7008 |
Hi,
thank you both very much!
Claus Wagner
"Sherlock" schrieb im Newsbeitrag
news:e85dac7e-364b-4e05-a9a2-e2ef2e16ba74@googlegroups.com...
snip[ I need a possibility to urlencode Strings. ]
FUNCTION UrlEncodeString( cRawString AS STRING ) AS STRING
LOCAL cURLEncodeOut := "" AS STRING
LOCAL cOneChar AS STRING
LOCAL xx, dwLength AS DWORD
dwLength := SLen(cRawString)
FOR xx := 1 UPTO dwLength
cOneChar := SubStr(cRawString, xx, 1)
//
IF At( cOneChar,
"ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789-_.~" ) > 0
cURLEncodeOut += cOneChar
ELSE
cURLEncodeOut += "%" + right(AsHexString(Asc(cOneChar)),2)
ENDIF
NEXT
//
RETURN cURLEncodeOut
[toc] | [prev] | [next] | [standalone]
| From | moshe attia <attiamx@gmail.com> |
|---|---|
| Date | 2016-03-15 07:34 -0700 |
| Message-ID | <bf973d65-d054-4954-b5f3-f7f447a1786b@googlegroups.com> |
| In reply to | #7006 |
On Thursday, June 26, 2014 at 3:57:44 PM UTC+3, Claus Wagner wrote: > Hi, > > I need a possibility to urlencode Strings. > Any hints? > > Thank you, > Claus Wagner hi BaseToBase ??? any body know the source ?
[toc] | [prev] | [standalone]
Back to top | Article view | comp.lang.clipper.visual-objects
csiph-web