Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]
Groups > comp.lang.clipper.visual-objects > #6221 > unrolled thread
| Started by | Alex <paidosoft@googlemail.com> |
|---|---|
| First post | 2013-11-09 01:27 -0800 |
| Last post | 2013-11-12 11:42 +0100 |
| Articles | 13 — 5 participants |
Back to article view | Back to comp.lang.clipper.visual-objects
DataWindows within TopAppWindows Alex <paidosoft@googlemail.com> - 2013-11-09 01:27 -0800
Re: DataWindows within TopAppWindows D.J.W. van Kooten <public@ic2remove.this.com> - 2013-11-10 23:42 +0100
Re: DataWindows within TopAppWindows paidosoft@googlemail.com - 2013-11-11 12:49 -0800
Re: DataWindows within TopAppWindows D.J.W. van Kooten <public@ic2remove.this.com> - 2013-11-11 23:07 +0100
Re: DataWindows within TopAppWindows antoshkovsp@gmail.com - 2013-11-11 21:17 -0800
Re: DataWindows within TopAppWindows D.J.W. van Kooten <public@ic2remove.this.com> - 2013-11-12 12:02 +0100
Re: DataWindows within TopAppWindows paidosoft@googlemail.com - 2013-11-12 12:10 -0800
Re: DataWindows within TopAppWindows "Gerhard Bunzel" <g.bunzel@domonet.de> - 2013-11-12 23:13 +0100
Re: DataWindows within TopAppWindows D.J.W. van Kooten <public@ic2remove.this.com> - 2013-11-13 11:58 +0100
Re: DataWindows within TopAppWindows paidosoft@googlemail.com - 2013-11-24 10:15 -0800
Re: DataWindows within TopAppWindows "Gerhard Bunzel" <g.bunzel@domonet.de> - 2013-11-24 22:15 +0100
Re: DataWindows within TopAppWindows paidosoft@googlemail.com - 2013-11-27 14:04 -0800
Re: DataWindows within TopAppWindows "Gerhard Bunzel" <g.bunzel@domonet.de> - 2013-11-12 11:42 +0100
| From | Alex <paidosoft@googlemail.com> |
|---|---|
| Date | 2013-11-09 01:27 -0800 |
| Subject | DataWindows within TopAppWindows |
| Message-ID | <1247b5f3-756e-428a-b5f9-3a552d8eee4c@googlegroups.com> |
From earlier posts I have understood that SEUIXP's draggable menus are not working on a ShellWindow. You need your application based on a TopAppWindow rather than a ShellWindow. So, ok, I changed my top window from ShellWindow to TopAppWindow. I am fine with that, but: my DataWindows show a completely different unwanted behavior. No caption bars anymore, and when maximizing they overlap the rebar. Isn't it possible to have DataWindows within a TopAppWindow properly working?
[toc] | [next] | [standalone]
| From | D.J.W. van Kooten <public@ic2remove.this.com> |
|---|---|
| Date | 2013-11-10 23:42 +0100 |
| Message-ID | <ga2089tbl3li21a69fa121ggh26adch1nm@4ax.com> |
| In reply to | #6221 |
On Sat, 9 Nov 2013 01:27:05 -0800 (PST), Alex
<paidosoft@googlemail.com> wrote:
Hello Alex,
>From earlier posts I have understood that SEUIXP's draggable menus are not working on a ShellWindow.
>You need your application based on a TopAppWindow rather than a ShellWindow.
>So, ok, I changed my top window from ShellWindow to TopAppWindow.
I am not sure what you mean by a 'draggable menu'. Or you must mean
the capability of SEUIXP for the end user to drag buttons to any
position. In that case I can assure you that this works on a shell
window. We do have our main menu on the shell window and windows based
on child windows, showing a second toolbar below the main shell window
menu.
I use a CLASS BasicToolBar and then a Precreate of 2 lines and a
Postcreate defining exactly what the toolbar shows. With lines like
this:
_oConfig:SetImageList(SETBImgList{FALSE,TRUE})
_oConfig:AddButton(55,IDM_iConnectEmptyShellMenu_MN_RELATIEBEHEER_MN_RELATIES_ID,Vt(CLM_ADRESHEADER,"Relaties"),Vt(MN_RELATIES))
the toolbar buttons are defined and connected to an existing shell
menu; _oConfig:Default := {55,56,58,59} determines which of the above
defined icons are actually displayed.
For childwindows I do the same on the level of their menu.
I can mail you my code if you still have trouble, but there are some
samples in the directory which should help you as well.
Dick
[toc] | [prev] | [next] | [standalone]
| From | paidosoft@googlemail.com |
|---|---|
| Date | 2013-11-11 12:49 -0800 |
| Message-ID | <bfbc19b9-4812-49ce-af88-ed83ce84208a@googlegroups.com> |
| In reply to | #6222 |
Dick, Thanks for your help. By 'draggable' I basically mean a menu on a rebar (with a drag handle). Sven comes with two examples: 1. SEUIXP MDI Sample This is based on a ShellWindow but the menu does not have a drag-handle and does look quite oldschool 2. SEUI XP ReBar Sample This is what I mean and what I want to realize. However, it is based on a TopAppWindow and it does not work with a ShellWindow. The submenus just don't open if I inherit from ShellWindow. If you have realized the latter, I'd be happy if you could share the code. Though from what you describe I assume you do not use rebars. My intention was thus to switch my app to TopAppWindow (as rebars seem to work there), but the DataWindows then show a strange behavior. Alex
[toc] | [prev] | [next] | [standalone]
| From | D.J.W. van Kooten <public@ic2remove.this.com> |
|---|---|
| Date | 2013-11-11 23:07 +0100 |
| Message-ID | <77l289l57evo7g5ugs6u2e5851im02do8s@4ax.com> |
| In reply to | #6227 |
On Mon, 11 Nov 2013 12:49:32 -0800 (PST), paidosoft@googlemail.com
wrote:
Hello Alex,
>2. SEUI XP ReBar Sample
>This is what I mean and what I want to realize. However, it is based on a TopAppWindow
>and it does not work with a ShellWindow.
>The submenus just don't open if I inherit from ShellWindow.
>
>If you have realized the latter, I'd be happy if you could share the code.
>Though from what you describe I assume you do not use rebars.
I think I do, see this picture in the link. There are 2 buttons on my
my shell toolbar with a menu added and several in some of the
underlying childwindows:
http://www.ic2.com/cavo/rebar.jpg
Code in the PostCreate is basically this:
LOCAL oMenu,oMenu2 AS SEMenuXP
......
_oConfig:AddButton(116,IDM_iConnectEmptyShellMenu_MN_HELP_MN_SAVETOOLBAR_ID,"Toolbar",;
"Toolbar"),BTNS_WHOLEDROPDOWN ) // Toolbarbutton with drop down menu,
defined below 26-7-2011
oMenu:=ToolbarOptionsMenu{}
SELF:SetDropDown(IDM_iConnectEmptyShellMenu_MN_HELP_MN_SAVETOOLBAR_ID,
oMenu) // Assign a menu to the above drop down menu button for the
toolbar
If this is what you mean and you need more code, just let me know and
I'll mail it.
Dick
[toc] | [prev] | [next] | [standalone]
| From | antoshkovsp@gmail.com |
|---|---|
| Date | 2013-11-11 21:17 -0800 |
| Message-ID | <c393c111-7643-46c7-b530-78bf38db4999@googlegroups.com> |
| In reply to | #6228 |
> > Hello Alex, > > > > > >If you have realized the latter, I'd be happy if you could share the code. > > >Though from what you describe I assume you do not use rebars. > > I think I do, see this picture in the link. There are 2 buttons on my > > my shell toolbar with a menu added and several in some of the > > > If this is what you mean and you need more code, just let me know and > > I'll mail it. > > Dick Hello Dick, Can you send me this code too? My email: antoshkov@mail.ru Best regards Sergey A
[toc] | [prev] | [next] | [standalone]
| From | D.J.W. van Kooten <public@ic2remove.this.com> |
|---|---|
| Date | 2013-11-12 12:02 +0100 |
| Message-ID | <1l248954o5fd55ok7tjda9p4kjmbjms1hq@4ax.com> |
| In reply to | #6229 |
On Mon, 11 Nov 2013 21:17:27 -0800 (PST), antoshkovsp@gmail.com wrote: Hello Sergey, >Can you send me this code too? >My email: antoshkov@mail.ru > Done! Dick
[toc] | [prev] | [next] | [standalone]
| From | paidosoft@googlemail.com |
|---|---|
| Date | 2013-11-12 12:10 -0800 |
| Message-ID | <e45baa96-7dd1-424e-90b2-0342de9c3692@googlegroups.com> |
| In reply to | #6231 |
Hi all, @Dick: thanks for the code! Brings me to new ideas for my toolbar that I might implement! However, I meant a separate menu such as this one: https://dl.dropboxusercontent.com/u/6142113/menu.jpg Here the menu does not drop down. Gerhard's code looks promising and might bring the solution. However, the code does not include the method __GetButtonDropDownMenu @Gerhard: could you share that one, too? Pressing the Alt key within the shellwindow does not lead to a focus on the menu - as it is the case with other menus. Any idea? Best Alex
[toc] | [prev] | [next] | [standalone]
| From | "Gerhard Bunzel" <g.bunzel@domonet.de> |
|---|---|
| Date | 2013-11-12 23:13 +0100 |
| Message-ID | <l5u94e$k3j$1@news.m-online.net> |
| In reply to | #6232 |
Alex, you will find the CLASS MyToolbar with all Methods you need in that VO-Sample: Toolbar True Color C:\cavo28\Samples\TOOLBAR That Sample is also with a TopAppWindow. But with the enhanced Method ControlNotify() this MyToolbar works within a ShellWindow. HTH Gerhard <paidosoft@googlemail.com> schrieb im Newsbeitrag news:e45baa96-7dd1-424e-90b2-0342de9c3692@googlegroups.com... > Hi all, > > @Dick: thanks for the code! Brings me to new ideas for my toolbar that I > might implement! > > However, I meant a separate menu such as this one: > > https://dl.dropboxusercontent.com/u/6142113/menu.jpg > > Here the menu does not drop down. Gerhard's code looks promising and might > bring the solution. However, the code does not include the method > __GetButtonDropDownMenu > > @Gerhard: could you share that one, too? > Pressing the Alt key within the shellwindow does not lead to a focus on > the menu - as it is the case with other menus. Any idea? > > Best > Alex > >
[toc] | [prev] | [next] | [standalone]
| From | D.J.W. van Kooten <public@ic2remove.this.com> |
|---|---|
| Date | 2013-11-13 11:58 +0100 |
| Message-ID | <umm689h7auvimbuacnm37bcmd6r0kd68dm@4ax.com> |
| In reply to | #6232 |
On Tue, 12 Nov 2013 12:10:04 -0800 (PST), paidosoft@googlemail.com wrote: Hello Alex, >@Dick: thanks for the code! Brings me to new ideas for my toolbar that I might implement! >However, I meant a separate menu such as this one: I can't see directly from the picture what is different compared to a normal menu. But I only use 'normal' menus + toolbar + the drop down menu's from a button which I sent. Hope it helps in your current or future programming Dick
[toc] | [prev] | [next] | [standalone]
| From | paidosoft@googlemail.com |
|---|---|
| Date | 2013-11-24 10:15 -0800 |
| Message-ID | <2a99b60c-0f41-4813-8dac-29e13841d3e8@googlegroups.com> |
| In reply to | #6234 |
Hi all, unfortunately I could not get your example working, Dick. The menu just won't drop down. So I tried to get the ControlNotify from Gerhard running. @Gerhard: The method that you use is not included in Cavo28 SP2 "Toolbar True Color" example (maybe in SP4?): oMenu := SELF:ToolBar:__GetButtonDropDownMenu ( struNMTB.hdr.hwndFrom, struNMTB.iItem ) I tried to implement the method by myself but I guess I am not very good in Win32 API programming. So I didn't succeed. Would you be so kind to share the AEF with me, or the method __GetButtonDropDownMenu? Would be of great help. Best wishes, Alex
[toc] | [prev] | [next] | [standalone]
| From | "Gerhard Bunzel" <g.bunzel@domonet.de> |
|---|---|
| Date | 2013-11-24 22:15 +0100 |
| Message-ID | <l6tq77$d08$1@news.m-online.net> |
| In reply to | #6275 |
Alex,
in that Sample 'Toolbar True Color' is a CLASS MyToolbar with that Method
Here is the complete Class:
STRUCT _winNMTOOLBAR
MEMBER hdr IS _winNMHDR
MEMBER iItem AS INT
MEMBER tbButton IS _winTBBUTTON
MEMBER cchText AS INT
MEMBER pszText AS PSZ
STRUCT _winTBBUTTONINFO
MEMBER cbSize AS DWORD
MEMBER dwMask AS DWORD
MEMBER idCommand AS INT
MEMBER iImage AS INT
MEMBER fsState AS BYTE
MEMBER fsStyle AS BYTE
MEMBER cx AS WORD
MEMBER lParam AS DWORD
MEMBER pszText AS PSZ
MEMBER cchText AS INT
CLASS MyToolbar INHERIT Toolbar
PROTECT _aDropDownMenus AS ARRAY
METHOD __GetButtonDropDownMenu ( hToolBar, nItemId ) CLASS MyToolBar
LOCAL struTBButton IS _winTBBUTTONINFO
LOCAL dwMask AS DWORD
LOCAL oMenu AS Menu
IF hToolbar != NULL_PTR
dwMask := TBIF_LPARAM
struTBButton.cbSize := _SIZEOF( _winTBBUTTONINFO )
struTBButton.dwMask := dwMask
SendMessage( hToolbar , TB_GETBUTTONINFO , nItemID , LONG( _CAST ,
@struTBButton ) )
oMenu := SELF:_aDropDownMenus [ struTBButton.lParam ]
ENDIF
RETURN oMenu
METHOD Destroy() CLASS MyToolbar
LOCAL i AS DWORD
SUPER:Destroy()
FOR i := 1 UPTO ALen ( SELF:_aDropDownMenus )
IF SELF:_aDropDownMenus [ i ] != NULL_OBJECT
SELF:_aDropDownMenus [ i ]:Destroy()
IF .NOT. InCollect()
SELF:_aDropDownMenus [ i ] := NULL_OBJECT
ENDIF
ENDIF
NEXT
RETURN NIL
METHOD EnableButtonCheck ( nItemID, symTB ) CLASS MyToolBar
LOCAL struTBButton IS _winTBBUTTONINFO
LOCAL dwMask AS DWORD
LOCAL hToolbar AS PTR
Default ( @symTB , #MAINTOOLBAR )
hToolbar := SELF:__FindToolbarhandle( symTB )
IF hToolbar != NULL_PTR
dwMask := TBIF_STYLE
struTBButton.cbSize := _SIZEOF( _winTBBUTTONINFO )
struTBButton.dwMask := dwMask
struTBButton.fsStyle := TBSTYLE_CHECK
SendMessage( hToolbar , TB_SETBUTTONINFO , nItemId , LONG( _CAST ,
@struTBButton ) )
ENDIF
METHOD EnableButtonCheckGroup ( nItemID, symTB ) CLASS MyToolBar
LOCAL struTBButton IS _winTBBUTTONINFO
LOCAL dwMask AS DWORD
LOCAL hToolbar AS PTR
Default ( @symTB , #MAINTOOLBAR )
hToolbar := SELF:__FindToolbarhandle( symTB )
IF hToolbar != NULL_PTR
dwMask := TBIF_STYLE
struTBButton.cbSize := _SIZEOF( _winTBBUTTONINFO )
struTBButton.dwMask := dwMask
struTBButton.fsStyle := TBSTYLE_CHECKGROUP
SendMessage( hToolbar , TB_SETBUTTONINFO , nItemId , LONG( _CAST ,
@struTBButton ) )
ENDIF
METHOD EnableButtonDropDown ( nItemId, symTB, oMenu, nSize ) CLASS MyToolBar
LOCAL struTBButton IS _winTBBUTTONINFO
LOCAL dwMask AS DWORD
LOCAL hToolbar AS PTR
Default ( @symTB , #MAINTOOLBAR )
hToolbar := SELF:__FindToolbarhandle( symTB )
IF hToolbar != NULL_PTR
AAdd ( _aDropDownMenus , oMenu )
// SendMessage( hToolbar , TB_SETEXTENDEDSTYLE , 0 , TBSTYLE_TRANSPARENT )
// SendMessage(hToolbar, TB_SETEXTENDEDSTYLE, 0, TBSTYLE_EX_DRAWDDARROWS)
IF IsNumeric ( nSize )
dwMask := _OR( TBIF_STYLE , TBIF_LPARAM , TBIF_SIZE )
ELSE
dwMask := _OR( TBIF_STYLE , TBIF_LPARAM )
ENDIF
struTBButton.cbSize := _SIZEOF( _winTBBUTTONINFO )
struTBButton.dwMask := dwMask
struTBButton.fsStyle := TBSTYLE_DROPDOWN
struTBButton.lParam := DWORD ( _CAST , ALen ( _aDropDownMenus ) )
IF IsNumeric ( nSize )
struTBButton.cx := nSize
ENDIF
SendMessage( hToolbar , TB_SETBUTTONINFO , nItemId , LONG( _CAST ,
@struTBButton ) )
ENDIF
DEFINE TB_GETBUTTONINFO := (WM_USER + 65)
DEFINE TB_SETBUTTONINFO := (WM_USER + 66)
DEFINE TB_SETEXTENDEDSTYLE := (WM_USER + 84)
DEFINE TBN_DROPDOWN := (TBN_FIRST - 10)
DEFINE TBSTYLE_DROPDOWN := 0x0008
DEFINE TBSTYLE_EX_DRAWDDARROWS := 0x00000001
TEXTBLOCK METHOD Dispatch (oEvent) CLASS MyToolbar
LOCAL StrucPaint IS _WinPaintStruct
LOCAL hDC AS PTR
LOCAL strucPaintRect AS _WinRect
LOCAL strucTBItemRect IS _WinRect
LOCAL i, dwItems, n AS DWORD
DO CASE
CASE oEvent:message == WM_Paint
IF SELF:background == NULL_OBJECT
SELF:setStyle (TBSTYLE_FLAT)
n := GetSysColor (COLOR_MENU)
SELF:background := Brush { Color { GetRValue (n), ;
GetGValue (n), ;
GetBValue (n) ;
} ;
}
ENDIF
hDC := BeginPaint (SELF:handle (), @strucPaint)
strucPaintRect := @strucPaint.rcPaint
FillRect (hDC, strucPaintRect, SELF:background:handle())
dwItems := SendMessage (SELF:handle (), TB_ButtonCount, 0, 0L)
FOR i:=0 UPTO dwItems
SendMessage (SELF:handle (), TB_GetItemRect, i, LONG (_CAST,
@strucTBItemRect))
// prüfen ob ein Button in der Exposed Area liegt
// (Flackern der Items verhindern)
IF Between (strucTBItemRect.left , strucPaintRect.left,
strucPaintRect.Right) .OR. ;
Between (strucTBItemRect.right, strucPaintRect.left, strucPaintRect.Right)
InvalidateRect (SELF:handle (), @strucTBItemRect, FALSE)
ENDIF
NEXT i
EndPaint (SELF:handle (), @strucPaint)
ENDCASE
RETURN SUPER:dispatch (oEvent)
?
METHOD IsChecked ( nItemID , symTB ) CLASS MyToolBar
LOCAL struTBInfo IS _winTBBUTTONINFO
LOCAL lSet AS LOGIC
LOCAL hToolbar AS PTR
// done
Default ( @symTB , #MAINTOOLBAR )
hToolbar := SELF:__FindToolbarhandle ( symTB )
IF hToolbar != NULL_PTR
struTBInfo.cbsize := _SIZEOF ( _winTBBUTTONINFO )
struTBInfo.dwmask := TBIF_STATE
SendMessage ( hToolbar , TB_GETBUTTONINFO , DWORD(nItemID) , LONG ( _CAST ,
@struTBInfo ) )
IF _AND ( struTBInfo.fsState , TBSTATE_CHECKED ) == TBSTATE_CHECKED
lSet := TRUE
ENDIF
ENDIF
RETURN lSet
METHOD SetButtonText( nItemID, symTB, cText ) CLASS MyToolBar
LOCAL struTBButton IS _winTBBUTTONINFO
LOCAL hToolbar AS PTR
LOCAL fsStyle AS BYTE
Default ( @symTB, #MAINTOOLBAR )
hToolbar := SELF:__FindToolbarhandle ( symTB )
IF hToolbar != NULL_PTR
struTBButton.cbSize := _SIZEOF( _winTBBUTTONINFO )
struTBButton.dwMask := TBIF_STYLE
SendMessage ( hToolbar, TB_GETBUTTONINFO, DWORD(nItemId), LONG( _CAST,
@struTBButton ) )
fsStyle := struTBButton.fsStyle
struTBButton.dwMask := _OR( TBIF_TEXT, TBIF_STYLE )
struTBButton.fsStyle := _OR(fsStyle, TBIF_STYLE, TBSTYLE_AUTOSIZE)
struTBButton.pszText := String2Psz( cText )
struTBButton.cchText := LONG( SLen( cText ) )
SendMessage ( hToolbar, TB_SETBUTTONINFO, DWORD(nItemId), LONG( _CAST,
@struTBButton ) )
ENDIF
RETURN
METHOD Init(oOwner, xID, oPoint, oDimension, lEnableBands) CLASS MyToolBar
SUPER:init(oOwner, xID, oPoint, oDimension, lEnableBands)
SELF:SetStyle(TBSTYLE_TRANSPARENT)
SELF:_aDropDownMenus := {}
RETURN SELF
HTH
Gerhard Bunzel
<paidosoft@googlemail.com> schrieb im Newsbeitrag
news:2a99b60c-0f41-4813-8dac-29e13841d3e8@googlegroups.com...
> Hi all,
>
> unfortunately I could not get your example working, Dick. The menu just
> won't drop down.
>
> So I tried to get the ControlNotify from Gerhard running.
>
> @Gerhard: The method that you use is not included in Cavo28 SP2 "Toolbar
> True Color" example (maybe in SP4?):
>
> oMenu := SELF:ToolBar:__GetButtonDropDownMenu ( struNMTB.hdr.hwndFrom,
> struNMTB.iItem )
>
> I tried to implement the method by myself but I guess I am not very good
> in Win32 API programming. So I didn't succeed. Would you be so kind to
> share the AEF with me, or the method __GetButtonDropDownMenu?
>
> Would be of great help.
>
> Best wishes,
> Alex
[toc] | [prev] | [next] | [standalone]
| From | paidosoft@googlemail.com |
|---|---|
| Date | 2013-11-27 14:04 -0800 |
| Message-ID | <2b4cb24f-8d0f-4a34-b590-9324e515eb67@googlegroups.com> |
| In reply to | #6276 |
Thanks, Gerhard! I will give it a try! Best regards, Alex
[toc] | [prev] | [next] | [standalone]
| From | "Gerhard Bunzel" <g.bunzel@domonet.de> |
|---|---|
| Date | 2013-11-12 11:42 +0100 |
| Message-ID | <l5t0la$bq9$1@news.m-online.net> |
| In reply to | #6221 |
Alex,
with that Code, your DropDownMenu should also work in a ShellWindow:
METHOD ControlNotify ( oControlNotifyEvent ) CLASS winShell
LOCAL oEvt AS ControlNotifyEvent
LOCAL struNMTB AS _winNMTOOLBAR
LOCAL oMenu AS OBJECT
LOCAL iMenuID AS INT
LOCAL rc IS _WINRECT
LOCAL nHeight AS LONG
// SUPER:ControlNotify ( oEvent )
oEvt := oControlNotifyEvent
IF oEvt:NotifyCode == TTN_NEEDTEXT
ProcessToolTip(SELF, oEvt)
ELSE
SUPER:ControlNotify(oEvt)
ENDIF
IF oEvt:NotifyCode == TBN_DROPDOWN
struNMTB := PTR(_CAST, oEvt:lParam)
iMenuID := struNMTB.iItem // <== This is your button ID (MENU ID)
SendMessage(struNMTB.hdr.hwndFrom, TB_GETRECT, DWORD(_CAST, struNMTB.iItem),
LONG(_CAST, @rc))
nHeight := rc.bottom
ClientToScreen ( struNMTB.hdr.hwndFrom, @rc )
oMenu := SELF:ToolBar:__GetButtonDropDownMenu ( struNMTB.hdr.hwndFrom,
struNMTB.iItem )
IF oMenu != NULL_OBJECT
oMenu:ShowAsPopUp(SELF, Point{rc.left, rc.top + nHeight})
SELF:cMenuName := Symbol2String(ClassName(oMenu))
ENDIF
ENDIF
RETURN NIL
HTH
Gerhard Bunzel
"Alex" <paidosoft@googlemail.com> schrieb im Newsbeitrag
news:1247b5f3-756e-428a-b5f9-3a552d8eee4c@googlegroups.com...
> From earlier posts I have understood that SEUIXP's draggable menus are not
> working on a ShellWindow. You need your application based on a
> TopAppWindow rather than a ShellWindow. So, ok, I changed my top window
> from ShellWindow to TopAppWindow.
>
> I am fine with that, but: my DataWindows show a completely different
> unwanted behavior. No caption bars anymore, and when maximizing they
> overlap the rebar.
>
> Isn't it possible to have DataWindows within a TopAppWindow properly
> working?
[toc] | [prev] | [standalone]
Back to top | Article view | comp.lang.clipper.visual-objects
csiph-web