Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]


Groups > comp.lang.clipper.visual-objects > #7007

Re: urlencode

Path csiph.com!v102.xanadu-bbs.net!xanadu-bbs.net!feeder.erje.net!eu.feeder.erje.net!fu-berlin.de!uni-berlin.de!individual.net!not-for-mail
From Karl Wochele <kw@e﹐s-system.dot.de>
Newsgroups comp.lang.clipper.visual-objects
Subject Re: urlencode
Date Thu, 26 Jun 2014 15:08:06 +0200
Lines 146
Message-ID <c12k9nF9s85U1@mid.individual.net> (permalink)
References <loh5c8$c52$1@news.albasani.net>
Mime-Version 1.0
Content-Type text/plain; charset=ISO-8859-1; format=flowed
Content-Transfer-Encoding 7bit
X-Trace individual.net kheAh0dlmC8/VNBmHwYMMA01Vb/lP6uLByKU1QBFmsz/hxA5zi
Cancel-Lock sha1:IsXNxSolakn2ApI7n69MpLZTiaM=
User-Agent Mozilla/5.0 (Windows NT 6.1; WOW64; rv:24.0) Gecko/20100101 Thunderbird/24.6.0
In-Reply-To <loh5c8$c52$1@news.albasani.net>
Xref csiph.com comp.lang.clipper.visual-objects:7007

Show key headers only | View raw


Hi Claus,

here are the functions I use:

FUNCTION UrlEncode(cText)
LOCAL cEncode	AS STRING
LOCAL pIn		AS BYTE PTR
LOCAL nLen		AS DWORD
LOCAL pOut		AS BYTE PTR
LOCAL pTemp		AS BYTE PTR
LOCAL n			AS DWORD
LOCAL vc			AS DWORD
LOCAL nOut		AS DWORD
LOCAL cHex		AS STRING
LOCAL nAlloc	AS DWORD

pIn		:= PTR(_CAST, StringAlloc(cText))
nLen		:= SLen(cText)
nAlloc	:= Max(nLen*3,10)
pOut		:= MemAlloc(nAlloc)

FOR n := 1 TO nLen

	IF nOut >= nAlloc-3
		nAlloc	+= Min(nLen,1024)
		pTemp		:= MemAlloc(nAlloc)
		MemCopy(pTemp,pOut,nOut)
		MemFree(pOut)
		pOut		:= pTemp		
	ENDIF

	vc		:= pIn[n]
	DO CASE
	CASE vc = 32
		nOut += 1
		pOut[nOut]	:= 43	//Asc("+")

	CASE InList(vc,Asc("!"),;
						Asc("#"),;
						Asc("$"),;
						Asc("%"),;
						Asc("&"),;
						Asc("'"),;
						Asc("("),;
						Asc(")"),;
						Asc("*"),;
						Asc("+"),;
						Asc(","),;
						Asc("/"),;
						Asc(":"),;
						Asc(";"),;
						Asc("="),;
						Asc("?"),;
						Asc("@"),;
						Asc("["),;
						Asc("]"))

		nOut += 1
		pOut[nOut]	:= Asc("%")
		cHex	:= Lower(BaseToBase(NTrim(vc),10,16,2))
		nOut += 1
		pOut[nOut]	:= Asc(Left(cHex,1))
		nOut += 1
		pOut[nOut]	:= Asc(Right(cHex,1))
	OTHERWISE
		nOut += 1
		pOut[nOut]	:= vc
	ENDCASE
NEXT n

MemFree(pIn)
cEncode := Mem2String(pOut,DWORD(nOut))
MemFree(pOut)

RETURN cEncode

FUNCTION UrlDecode(cText)
LOCAL cDecode	AS STRING
LOCAL nOut		AS DWORD
LOCAL pIn		AS BYTE PTR
LOCAL nLen		AS DWORD
LOCAL pOut		AS BYTE PTR
LOCAL pTemp		AS BYTE PTR
LOCAL n			AS DWORD
LOCAL vc			AS DWORD
LOCAL cHex		AS STRING
LOCAL nAlloc	AS DWORD

pIn		:= PTR(_CAST, StringAlloc(cText))
nLen		:= SLen(cText)
nAlloc	:= Max(nLen,10)
pOut		:= MemAlloc(nAlloc)

FOR n := 1 TO nLen

	IF nOut >= nAlloc-3
		nAlloc	+= Min(nLen,1024)
		pTemp		:= MemAlloc(nAlloc)
		MemCopy(pTemp,pOut,nOut)
		MemFree(pOut)
		pOut		:= pTemp		
	ENDIF

	vc		:= pIn[n]

	DO CASE
	CASE vc = Asc("%")
		n += 1
		vc := pIn[n]
		cHex := CHR(vc)
		n += 1
		vc := pIn[n]
		cHex += CHR(vc)
		nOut += 1
		pOut[nOut]	:= Val(BaseToBase(cHex,16,10,3))
	CASE vc = Asc("+")
		nOut += 1
		pOut[nOut]	:= 32	//Asc(" ")
	OTHERWISE
		nOut += 1
		pOut[nOut]	:= vc
	ENDCASE

NEXT n

MemFree(pIn)
cDecode := Mem2String(pOut,DWORD(nOut))
MemFree(pOut)


RETURN cDecode


HTH
Karl


Am 26.06.2014 14:57, schrieb Claus Wagner:
> Hi,
>
> I need a possibility to urlencode Strings.
> Any hints?
>
> Thank you,
> Claus Wagner
>

Back to comp.lang.clipper.visual-objects | Previous | Next — Previous in thread | Next in thread | Find similar | Unroll thread


Thread

urlencode "Claus Wagner" <cwagner@laufwerk.net> - 2014-06-26 14:57 +0200
  Re: urlencode Karl Wochele <kw@e©os-system.dot.de> - 2014-06-26 15:08 +0200
  Re: urlencode Sherlock <sherlock@sherlock.com.au> - 2014-06-26 06:29 -0700
    Re: urlencode Karl Wochele <kw@e©os-system.dot.de> - 2014-06-27 08:27 +0200
    Re: urlencode "Claus Wagner" <cwagner@laufwerk.net> - 2014-06-27 09:53 +0200
  Re: urlencode moshe attia <attiamx@gmail.com> - 2016-03-15 07:34 -0700

csiph-web