Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]
Groups > comp.lang.clipper.visual-objects > #4889
| Path | csiph.com!usenet.pasdenom.info!weretis.net!feeder4.news.weretis.net!nuzba.szn.dk!pnx.dk!fu-berlin.de!uni-berlin.de!individual.net!not-for-mail |
|---|---|
| From | Karl Wochele <kw@e﹐s-system.de> |
| Newsgroups | comp.lang.clipper.visual-objects |
| Subject | Re: BLAT Wrapper (email command line EXE) |
| Date | Fri, 08 Mar 2013 12:00:11 +0100 |
| Lines | 227 |
| Message-ID | <aptulrFetkkU1@mid.individual.net> (permalink) |
| References | <0b1f1304-5ba4-4242-8081-980137e12c2c@googlegroups.com> <aptlj0Fct80U1@mid.individual.net> |
| Mime-Version | 1.0 |
| Content-Type | text/plain; charset=ISO-8859-1; format=flowed |
| Content-Transfer-Encoding | 7bit |
| X-Trace | individual.net DnzGFTyxQRkSZoNzHTaYSAvnx2/E5UjMtOiIWUzMg3lpyCcGNvbCObcdIfIuYmQqEe |
| Cancel-Lock | sha1:oq57iOXKTt6w/a7poLRtp5EHOG4= |
| User-Agent | Mozilla/5.0 (Windows NT 6.1; WOW64; rv:17.0) Gecko/20130215 Thunderbird/17.0.3 |
| In-Reply-To | <aptlj0Fct80U1@mid.individual.net> |
| Xref | csiph.com comp.lang.clipper.visual-objects:4889 |
Show key headers only | View raw
forgot to mention that you can use blat.dll and don't need blat.exe...
Karl
Am 08.03.2013 09:25, schrieb Karl Wochele:
> Hi Kevin,
>
> I once did some tests with blat and stopped it due to the fact that I
> couldn't use aliases for attachments. Here is my attempt:
>
> CLASS BlatMail
> PROTECT _CommandLine AS STRING
> PROTECT _LogFile AS STRING
> PROTECT AttachMents AS ARRAY
>
> PROTECT _IsValid AS LOGIC
>
> EXPORT Server AS STRING
> EXPORT UserName AS STRING
> EXPORT Password AS STRING
>
> EXPORT FromAddress AS STRING
> EXPORT FromName AS STRING
> EXPORT Subject AS STRING
> EXPORT DestList AS ARRAY
> EXPORT CCList AS ARRAY
> EXPORT BCCList AS ARRAY
>
> EXPORT MailBody AS STRING
> EXPORT BodyHTML AS STRING
> EXPORT ResultString AS STRING
>
> DECLARE ACCESS CommandLine
> DECLARE ACCESS IsValid
>
> DECLARE METHOD AddAttachment
> DECLARE METHOD AddCommand
> DECLARE METHOD ARRAY2List
> METHOD AddAttachment(cFile AS STRING,cAlias AS STRING) AS VOID PASCAL
> CLASS BlatMail
>
> // alias doesn't work ...
> AAdd(SELF:AttachMents,{cFile,cAlias})
>
> RETURN
>
> METHOD AddCommand(cOption AS STRING,cValue := "" AS STRING) AS VOID
> PASCAL CLASS BlatMail
>
> cOption := "-"+AllTrim(cOption)
>
> cValue := AllTrim(cValue)
> cValue := StrTran(cValue,'"','\"')
> SELF:_CommandLine += cOption+" "
> IF !Empty(cValue)
> cValue := Ansi2Oem(cValue)
> SELF:_CommandLine += '"'+cValue+'" '
> ENDIF
>
> RETURN
>
> METHOD ARRAY2List(a AS ARRAY) AS STRING PASCAL CLASS BlatMail
> LOCAL cList AS STRING
> LOCAL n AS DWORD
>
> cList := ""
> FOR n := 1 UPTO ALen(a)
> IF !Empty(cList)
> cList += ","
> ENDIF
> cList += AllTrim(a[n])
> NEXT n
>
> RETURN cList
> ACCESS CommandLine AS STRING PASCAL CLASS BlatMail
> LOCAL n AS DWORD
> LOCAL cCmd AS STRING
>
> SELF:_CommandLine := ""
>
> cCmd := SELF:ARRAY2List(SELF:DestList)
> SELF:AddCommand("to",cCmd)
>
> cCmd := SELF:ARRAY2List(SELF:CCList)
> IF !Empty(cCmd)
> SELF:AddCommand("cc",cCmd)
> ENDIF
>
> cCmd := SELF:ARRAY2List(SELF:BCCList)
> IF !Empty(cCmd)
> SELF:AddCommand("bcc",cCmd)
> ENDIF
>
> SELF:AddCommand("f",SELF:FromAddress)
> IF !Empty(SELF:FromName)
> SELF:AddCommand("i",SELF:FromName)
> ENDIF
> IF !Empty(SELF:Subject)
> SELF:AddCommand("s",SELF:Subject)
> ELSE
> SELF:AddCommand("ss")
> ENDIF
> IF !Empty(SELF:BodyHTML)
> SELF:AddCommand("body",SELF:BodyHTML)
> SELF:AddCommand("html")
> SELF:AddCommand("alttext",SELF:MailBody)
> ELSE
> SELF:AddCommand("body",SELF:MailBody)
> ENDIF
>
>
> SELF:AddCommand("server",SELF:Server)
> IF !Empty(SELF:UserName)
> SELF:AddCommand("u",SELF:UserName)
> IF !Empty(SELF:Password)
> SELF:AddCommand("pw",SELF:Password)
> ENDIF
> ENDIF
>
> FOR n := 1 UPTO ALen(SELF:AttachMents)
> SELF:AddCommand("attach",'"'+AllTrim(SELF:AttachMents[n][1])+'"')
> NEXT n
>
>
> // Use a logfile ?
> // SELF:_LogFile := TempFile()
> // SELF:AddCommand("log",SELF:_LogFile)
>
> SELF:AddCommand("noh2")
>
>
> SELF:AddCommand("charset","iso-8859-1")
>
> RETURN SELF:_CommandLine
>
> METHOD Init() CLASS BlatMail
> LOCAL hLib AS PTR
>
> IF hFunc = NULL_PTR
> hLib := LoadLibrary(PSZ("Blat.dll"))
> IF hLib <> NULL_PTR
> hFunc := GetProcAddress(hLib,PSZ("Send"))
> ENDIF
> ENDIF
>
> IF hFunc <> NULL_PTR
> SELF:_IsValid := TRUE
> ENDIF
>
> SELF:DestList := {}
> SELF:CCList := {}
> SELF:BCCList := {}
> SELF:AttachMents := {}
>
> RETURN SELF
>
> ACCESS IsValid AS LOGIC PASCAL CLASS BlatMail
> RETURN SELF:_IsValid
> METHOD Send() CLASS BlatMail
> LOCAL nResult AS INT
> LOCAL cCmd AS STRING
> LOCAL pCmd AS PSZ
>
> cCmd := SELF:CommandLine
>
> // TextBox{,"Cmd",cCmd,BUTTONOKAY}:Show()
>
>
> IF !Empty(SELF:_LogFile)
> FErase(SELF:_LogFile)
> ENDIF
>
> pCmd := StringAlloc(cCmd)
> nResult := INT(_CAST,PCALL(hFunc,pCmd))
> MemFree(pCmd)
>
> IF !Empty(SELF:_LogFile)
> SELF:ResultString := MemoRead(SELF:_LogFile)
> FErase(SELF:_LogFile)
> ELSE
> SELF:ResultString := ""
> ENDIF
>
> RETURN nResult
>
> STATIC GLOBAL hFunc AS PTR
>
> FUNCTION TestBlatMail() AS LOGIC
> LOCAL nResult AS INT
> LOCAL oMail AS BlatMail
>
> oMail := BlatMail{}
>
> IF oMail:IsValid
>
> oMail:Server := "xxx.yyy.zzz.a"
>
> oMail:FromAddress := "info@xxx.de"
> oMail:DestList := {"aa@bbb.de"}
> oMail:Subject := 'Testmail mit "Blat.DLL"'
> oMail:MailBody := "testmail"+CRLF+'Nummer
> "1"'+CHR(9)+'"XXXXXXX"'+CRLF+CRLF+"Ende"
>
> oMail:AddAttachment("C:\test.pdf","order.pdf")
>
> nResult := oMail:Send()
> IF nResult <> 0
> InfoBox{,,NTrim(nResult)+CRLF+oMail:ResultString}:Show()
> ENDIF
>
> ELSE
> InfoBox{,"Fehler","BlatMail kann nicht initialisiert werden"}:Show()
> ENDIF
>
> RETURN (nResult=0)
>
>
>
> HTH
> Karl
>
> Am 08.03.2013 04:56, schrieb baksoftgroup@gmail.com:
>> Has anyone used BLAT from inside VO to send emails?
>> If so, was it successful? And can you share any code?
>> Cheers
>> Kevin
>>
Back to comp.lang.clipper.visual-objects | Previous | Next — Previous in thread | Next in thread | Find similar | Unroll thread
BLAT Wrapper (email command line EXE) baksoftgroup@gmail.com - 2013-03-07 19:56 -0800
Re: BLAT Wrapper (email command line EXE) Karl Wochele <kw@e©os-system.de> - 2013-03-08 09:25 +0100
Re: BLAT Wrapper (email command line EXE) Karl Wochele <kw@e©os-system.de> - 2013-03-08 12:00 +0100
Re: BLAT Wrapper (email command line EXE) marc3l0 <mmarloch@gmail.com> - 2013-03-08 06:28 -0800
Re: BLAT Wrapper (email command line EXE) baksoftgroup@gmail.com - 2013-03-11 13:47 -0700
csiph-web