Groups | Search | Server Info | Keyboard shortcuts | Login | Register [http] [https] [nntp] [nntps]

Groups > comp.lang.basic.misc > #33

Re: HotPaw for iPod touch 3rd. Gen.

Show all headers | View raw

"PodMan"  wrote in message 
news:efde2ad9-28ce-4d2f-a1b9-8add99e9abfc@f15g2000pro.googlegroups.com...

I have an iPod, I have a working HotPaws Basic app., I know about the
SAVE command, the LOAD command and LIST, but I cannot find a way to
delete the programs I have saved.
Everytime I type in DIR they are still all there, - some suggestions
would be appreciated about now!

8^) is a smiley with glasses (turn your head to the left to see it better)

To plot points, here are the graphics commands:

  moveto x,y
  lineto x,y      :' draws a line to x,y
  fn color(r,g,b)
  fn linewidth(w)
  cls          :' clears display
  fn plot1()    :' see chipmunk basic documentation
  fn touch(1)    :' x location in graphics display
  fn touch(2)    :' y location in graphics display
  graphics cls  :' clears graphics display
  cls        :' clears both text and graphics

To set a single point, (x,y) do this:

moveto x,y : lineto x,y

This will set the graphics pen to x,y then draw from there to itself
which sets one point.  Here's a sample Mandelbrot program
to illustrate. You can copy and paste this into HotPaw:

5 option base 1
10 dim c(16,3)
20 mat read c
30 data 0,0,170,0,170,0,0,170,170,170,0,0
40 data 170,0,170,170,170,0
50 data 180,170,170,85,85,85
60 data 0,0,255,0,255,0,0,255,255
70 data 255,0,0,255,0,255
80 data 255,255,0,255,255,255
90 data 0,0,0
100 xmax = 319 : ymax = 213
110 cls
120 maxcolor = 16
130 leftside = -2
140 top = 1.25
150 xside = 2.5
160 yside = -2.5
170 xscale = xside/xmax
180 yscale = yside/ymax
190 for y = 1 to ymax/2
200 for x = 1 to xmax
210 cx = x*xscale+leftside
220 cy = y*yscale+top
230 zx = 0
240 zy = 0
250 colorcount = 0
260 while (zx*zx+zy*zy) < 4 and colorcount < maxcolor
270 tempx = zx*zx-zy*zy+cx
280 zy = 2*zx*zy+cy
290 zx = tempx
300 colorcount = colorcount+1
310 wend
320 graphics color c(colorcount,1),c(colorcount,2),c(colorcount,3)
330 moveto x,y : lineto x,y
340 moveto x,ymax-y : lineto x,ymax-y
350 next
360 next

Tom L 

Back to comp.lang.basic.misc | Previous | Next — Previous in thread | Find similar

Thread

HotPaw for iPod touch 3rd. Gen. PodMan <ipodeer@gmail.com> - 2011-05-09 22:35 -0700
  Re: HotPaw for iPod touch 3rd. Gen. "Tom Lake" <tlake@twcny.rr.com> - 2011-05-10 10:10 -0400
  Re: HotPaw for iPod touch 3rd. Gen. "Tom Lake" <tlake@twcny.rr.com> - 2011-05-10 21:27 -0400

csiph-web