Groups | Search | Server Info | Login | Register

Groups > comp.sys.sinclair > #7211

Hitomezashi

Show all headers | View raw

Seeing this video https://www.youtube.com/watch?v=JbfhzlMk2eY
about creating random hitomezashi-patterns inspired me to create this:
http://balglaas.sdf.org/hitomezashi/hitomezashi.html
but also to create this:

  10 REM Hitomezashi
  20 LET l=5
  30 LET w=240
  40 LET h=150
  50 RANDOMIZE
  60 REM === Border ========
  70 PLOT 0,0
  80 DRAW w+l,0
  90 DRAW 0,h+l
 100 DRAW -(w+l),0
 110 DRAW 0,-(h+l)
 120 REM === Vertical ======
 130 LET i=1
 140 GO SUB 370
 150 LET j=0
 160 IF dp=0 THEN GO TO 190
 170 PLOT l*i,l*j
 180 DRAW 0,l
 190 LET dp=1-dp
 200 LET j=j+1
 210 IF j*l<=h THEN GO TO 160
 220 LET i=i+1
 230 IF i*l<=w THEN GO TO 140
 240 REM === Horizontal ====
 250 LET j=1
 260 GO SUB 370
 270 LET i=0
 280 IF dp=0 THEN GO TO 310
 290 PLOT l*i,l*j
 300 DRAW l,0
 310 LET dp=1-dp
 320 LET i=i+1
 330 IF i*l<=w THEN GO TO 280
 340 LET j=j+1
 350 IF j*l<=h THEN GO TO 260
 360 STOP
 370 REM === Startpunt =====
 380 LET dp=INT (2*RND)
 390 RETURN



  ||/\||
  ||/\||
  ||  ||
  ||\/||
  ||\/||

Back to comp.sys.sinclair | Previous | Next — Next in thread | Find similar

Thread

Hitomezashi balglaas@xs4all.nl (Jan van den Broek) - 2026-03-02 21:09 +0100
  Re: Hitomezashi Damian Murphy <murf@the177project.org> - 2026-03-06 15:43 +0000
    Re: Hitomezashi Jan van den Broek <balglaas@dds.nl> - 2026-03-07 16:02 +0000
  Re: Hitomezashi Peter 'Shaggy' Haywood <phaywood@alphalink.com.au> - 2026-03-13 00:11 +1100
    Re: Hitomezashi Jan van den Broek <balglaas@dds.nl> - 2026-03-12 21:10 +0000

csiph-web